Remove both rows if there are duplicates in column B

[John T]

Hi,
I need a macro to delete the entire row if there are any duplicates in column B. This includes the original entry row and the duplicate row.
I have been using a macro that does this but occasionally it returns an error and i am unable to work out why.
Can anybody help me with my code or give me an alternative code that will work.
Many Thanks
This is my current code:

Sub quicker_Option()

    Dim toDel(), i As Long
    Dim RNG As Range, Cell As Long
    Set RNG = Range("b2:b200") 'set your range here

    For Cell = 1 To RNG.Cells.Count
        If Application.CountIf(RNG, RNG(Cell)) > 1 Then
            ReDim Preserve toDel(i)
            toDel(i) = RNG(Cell).Address
            i = i + 1
        End If
    Next
    For i = UBound(toDel) To LBound(toDel) Step -1
        Range(toDel(i)).EntireRow.Delete

    Next i

End Sub

 

[Fluff]

How about

Sub JohnT()
   Dim Cl As Range, Rng As Range
   
   With CreateObject("Scripting.dictionary")
         For Each Cl In Range("B2", Range("B" & Rows.Count).End(xlUp))
         If Not .Exists(Cl.Value) Then
            .Add Cl.Value, Cl
         Else
            If Rng Is Nothing Then Set Rng = Union(Cl, .Item(Cl.Value)) Else Set Rng = Union(Rng, Cl, .Item(Cl.Value))
         End If
      Next Cl
   End With
   If Not Rng Is Nothing Then Rng.EntireRow.Delete
End Sub