Removing Left Text from a Cell with condition VBA

[TeckTeck]

Hi i would like to remove everything that is on the left side of the cell value with 2 conditons

Condition 1: Start removing the left side of the cell when "P" is found and followed by a number Or
Condition 2: Start removing the left side of the cell when "PO" is found and followed by a number

I have tried this code but it doesnt seem to meet my conditions when more there are more than 1 "P" inside the cell and it also doesnt work when "PO" is inside the cell as shown in Column B row 3 and row 2 respectively. Please advice on how i can modify my code to make it work.

Sub deleteleft()
 
Dim ws As Worksheet
Dim LR As Long
Dim cell As Range
Dim startPosition As Long
 
Set ws = ThisWorkbook.Sheets("Sheet1")
 
 
LR = ws.Cells(ws.Rows.Count, "B").End(xlUp).Row
 
For Each cell In ws.Range("B2:B" & LR)
   If VarType(cell.Value) = vbString Then
       startPosition = InStr(1, cell.Value, "P", vbTextCompare)

       If startPosition > 0 Then
           If IsNumeric(Mid(cell.Value, startPosition + 1, 1)) Or (Mid(cell.Value, startPosition + 1, 2) = "O" And IsNumeric(Mid(cell.Value, startPosition + 2, 1))) Then
               cell.Value = Mid(cell.Value, startPosition)
           End If
       End If
   End If
Next cell
 
  
End Sub

 

[Peter_SSs]

When posting vba code in the forum, please use the available code tags. It makes your code much easier to read/debug & copy. My signature block below has more details. I have added the tags for you this time.

Also, please investigate XL2BB for providing sample data to make it easier for helpers by not having to manually type out sample data to test with.

Give this a try with a copy of your workbook. Note that it will not work in your Mac environment, only Windows.

Sub RemoveLeft()
  Dim RX As Object
  Dim a As Variant
  Dim i As Long
 
  Set RX = CreateObject("VBScript.RegExp")
  RX.Pattern = "(^.*?)(PO?\d.*)"
  With Range("B2", Range("B" & Rows.Count).End(xlUp))
    a = .Value
    For i = 1 To UBound(a)
      a(i, 1) = RX.Replace(a(i, 1), "$2")
    Next i
    .Value = a
  End With
End Sub

 

[TeckTeck]

When posting vba code in the forum, please use the available code tags. It makes your code much easier to read/debug & copy. My signature block below has more details. I have added the tags for you this time.

Also, please investigate XL2BB for providing sample data to make it easier for helpers by not having to manually type out sample data to test with.

Give this a try with a copy of your workbook. Note that it will not work in your Mac environment, only Windows.

Sub RemoveLeft()
  Dim RX As Object
  Dim a As Variant
  Dim i As Long
 
  Set RX = CreateObject("VBScript.RegExp")
  RX.Pattern = "(^.*?)(PO?\d.*)"
  With Range("B2", Range("B" & Rows.Count).End(xlUp))
    a = .Value
    For i = 1 To UBound(a)
      a(i, 1) = RX.Replace(a(i, 1), "$2")
    Next i
    .Value = a
  End With
End Sub

Hi Peter thank you for your code and advice, it work perfectly. I would heed your advice next well ! Thank you so much

 

[Peter_SSs]

You're welcome. Glad it worked for you. Thanks for the follow-up.