Rename tabs to cell values

[Nuttie10]

Good day guys, I'm sure someone will be able to help me.
I'm new to VBA (know nothing) and found a macro i can use to rename my tabs to cell values on each new worksheet, sometimes over a hundred worksheets(time sheets) depending on the amount of guys on site. It works well but i need three other worksheets to stay unchanged.

The code:

Sub RenameFromA1()
Dim Msg As String, i As Integer
For i = 1 To Sheets.Count
If Sheets(i).Range("U17").Value = "" Then
Msg = "Sheet " & i & "(" & Sheets(i).Name & ") has no value in U17. Fix sheet, then rerun."
MsgBox Msg, vbExclamation
Exit Sub
Else
On Error GoTo ErrSheetName
Sheets(i).Name = Sheets(i).Range("U17").Value
On Error GoTo 0
End If
Next i
Exit Sub
ErrSheetName: Msg = "Sheet " & i & "(" & Sheets(i).Name & ") could not be renamed. Check if name already used."
MsgBox Msg, vbExclamation

End Sub

 

[VoG]

What are the names of the sheets to be excluded?

 

[ogo]

For the worksheet to stay with their oldnames you can use If not statement.
For example:

'Assume that the name of the sheet that needs to be unchanged is 'Sheet1
if not Sheets(i).Name = "Sheets1" then
  Sheets(i).Name = Sheets(i).Range("U17").Value
end if

 

[Nuttie10]

Thanx for the speedy reply.
Do i have to just add it before END IF?

 

[ogo]

That should work.

 

[Nuttie10]

I must be doing something wrong because it doesn't work.
The name of the two worksheets that need to stay unchanged are "Employee List & Timesheet"

 

[VoG]

Try

Sub RenameFromA1()
Dim Msg As String, i As Integer
For i = 1 To Sheets.Count
    Select Case Sheets(i).Name
        Case "Employee List", "Timesheet"
            'do nothing
        Case Else
            If Sheets(i).Range("U17").Value = "" Then
                Msg = "Sheet " & i & "(" & Sheets(i).Name & ") has no value in U17. Fix sheet, then rerun."
                MsgBox Msg, vbExclamation
                Exit Sub
            Else
                On Error GoTo ErrSheetName
                Sheets(i).Name = Sheets(i).Range("U17").Value
                On Error GoTo 0
            End If
        End Select
Next i
Exit Sub
ErrSheetName: Msg = "Sheet " & i & "(" & Sheets(i).Name & ") could not be renamed. Check if name already used."
MsgBox Msg, vbExclamation
End Sub

 

[Nuttie10]

Thanks a MILLION.
I gotta learn how to use VBA.
Can you perhaps recommend any good books or online sites to teach myself VBA,
I have very limited resources.
Thank you very much VoG, your help is greatly appreciated.

 

[VoG]

Take a look at Hiker's list http://www.mrexcel.com/forum/showpost.php?p=2676997&postcount=5