Return date of Wednesday's during a specific month in a row

[BURN11]

A2=1/2023, I need B2 to contain the date of the first Wednesday of 1/2023; B3 to contain the date of the second Wednesday; B4 to contain the date of the third Wednesday; B5 to contain the date of the 4th Wednesday and B6 to contain the date of the 5th Wednesday or "N/A". Continuing this formula for all the months of the year.
Any assistance would be greatly appreciated.

 

[Dave Patton]

I rushed out the door and did not complete the post.
You can try the suggestion on a clean sheet.
Click on the icon below the f(x) in the heading, then move to your sheet and paste in cell B5.

LAMBDA.xlsm
	B	C	D	E	F	G
5	Date	1	2	3	4	5
6	01-Jan-23	Wed 4-Jan	Wed 11-Jan	Wed 18-Jan	Wed 25-Jan	N/A
7	01-Feb-23	Wed 1-Feb	Wed 8-Feb	Wed 15-Feb	Wed 22-Feb	N/A
8	01-Mar-23	Wed 1-Mar	Wed 8-Mar	Wed 15-Mar	Wed 22-Mar	Wed 29-Mar
9	01-Apr-23	Wed 5-Apr	Wed 12-Apr	Wed 19-Apr	Wed 26-Apr	N/A
10	01-May-23	Wed 3-May	Wed 10-May	Wed 17-May	Wed 24-May	Wed 31-May
11	01-Jun-23	Wed 7-Jun	Wed 14-Jun	Wed 21-Jun	Wed 28-Jun	N/A
12	01-Jul-23	Wed 5-Jul	Wed 12-Jul	Wed 19-Jul	Wed 26-Jul	N/A
13	01-Aug-23	Wed 2-Aug	Wed 9-Aug	Wed 16-Aug	Wed 23-Aug	Wed 30-Aug
14	01-Sep-23	Wed 6-Sep	Wed 13-Sep	Wed 20-Sep	Wed 27-Sep	N/A
15	01-Oct-23	Wed 4-Oct	Wed 11-Oct	Wed 18-Oct	Wed 25-Oct	N/A
16	01-Nov-23	Wed 1-Nov	Wed 8-Nov	Wed 15-Nov	Wed 22-Nov	Wed 29-Nov
17	01-Dec-23	Wed 6-Dec	Wed 13-Dec	Wed 20-Dec	Wed 27-Dec	N/A
9d

Cell Formulas
Range	Formula
C6:G17	C6	=LET(x,WORKDAY.INTL($B6-1,C$5,"1101111"),IF(MONTH(x)=MONTH(B6),x,"N/A"))

 

[BURN11]

Thank you so much! Works like a champ!

 

[Dave Patton]

Thanks for the feedback.

I recommend using actual dates for the Date column (like 1/1/2023) as shown in post # 11 or in example below.
This is more reliable than coercing the date or using some other shortcuts that do not work with all versions of Excel.
However, with text like 1/2023 in the date column; the formula will work.
=LET(d,$B6-1,x,WORKDAY.INTL(d,C$5,"1101111"),IF(x-DAY(x)=d,x,"N/A"))
At least on my system, the formula coerces the text to the correct value for the formula.

A slightly different example that you can consider.

LAMBDA.xlsm
	B	C	D	E	F	G
1	Year	2023
2
3
4
5	Date	1	2	3	4	5
6	1-Jan-23	Wed 4-Jan	Wed 11-Jan	Wed 18-Jan	Wed 25-Jan	N/A
7	1-Feb-23	Wed 1-Feb	Wed 8-Feb	Wed 15-Feb	Wed 22-Feb	N/A
8	1-Mar-23	Wed 1-Mar	Wed 8-Mar	Wed 15-Mar	Wed 22-Mar	Wed 29-Mar
9	1-Apr-23	Wed 5-Apr	Wed 12-Apr	Wed 19-Apr	Wed 26-Apr	N/A
10	1-May-23	Wed 3-May	Wed 10-May	Wed 17-May	Wed 24-May	Wed 31-May
11	1-Jun-23	Wed 7-Jun	Wed 14-Jun	Wed 21-Jun	Wed 28-Jun	N/A
12	1-Jul-23	Wed 5-Jul	Wed 12-Jul	Wed 19-Jul	Wed 26-Jul	N/A
13	1-Aug-23	Wed 2-Aug	Wed 9-Aug	Wed 16-Aug	Wed 23-Aug	Wed 30-Aug
14	1-Sep-23	Wed 6-Sep	Wed 13-Sep	Wed 20-Sep	Wed 27-Sep	N/A
15	1-Oct-23	Wed 4-Oct	Wed 11-Oct	Wed 18-Oct	Wed 25-Oct	N/A
16	1-Nov-23	Wed 1-Nov	Wed 8-Nov	Wed 15-Nov	Wed 22-Nov	Wed 29-Nov
17	1-Dec-23	Wed 6-Dec	Wed 13-Dec	Wed 20-Dec	Wed 27-Dec	N/A
7__3

Cell Formulas
Range	Formula
C5:G5	C5	=SEQUENCE(,5)
B6:B17	B6	=DATE(C1,SEQUENCE(12),1)
C6:G17	C6	=LET(d,$B6-1,x,WORKDAY.INTL(d,C$5,"1101111"),IF(x-DAY(x)=d,x,"N/A"))
Dynamic array formulas.