Return Name of 1st, 2nd, 3rd, etc. most popular items

[IteachThings]

Hello,

I am trying to sift through a bunch of data aggregated into a table. What I would like to do is find a way to have the top x choices listed by name in a separate part of the sheet without the same item being listed twice. My table currently looks like:

Item Code	Item Name	Item Score
A	Item A Name	11
B	Item B Name	10
C	Item C Name	10
D	Item D Name	8
E	Item E Name	11
F	Item F Name	5

The formula I am using right now is returning duplicate answers, as in 'Item A Name' twice, instead of listing 1st as "Item A Name" and 2nd as "Item E Name". The output format is also currently 'Item A name scored n" where n is the number of votes. I would like to keep that output if possible.

This is what I have currently:
=INDEX(B2:B7,MATCH(LARGE(C2:C7,1),C2:C7,FALSE),)&" scored "&LARGE(C2:C7,1) for the second value it would look like =INDEX(B2:B7,MATCH(LARGE(C2:C7,2),C2:C7,FALSE),)&" scored "&LARGE(C2:C7,2). Any help is appreciated.

 

[jimrward]

As you have ties in the votes you need to decide what your tie break criteria is and factor that in
for instance if your item code is indeed A-F or A-Z in reality, does it mean that if there is a tie as in your example A takes precedence over E as it’s nearer the start of the alphabet or do you have some other criteria

 

[IteachThings]

I don't have a preference for a tie breaker. If both would be listed next to each other, I would be ok using the "tie breaker" being alphabetical. In other words, it would be fine if there is a tie between code A and code E, if code A is listed first because it is first alphabetically. I don't have a particular criteria that I need for setting a precedent order.

 

[Eric W]

How about:

Book1
	A	B	C	D	E
1	Item Code	Item Name	Item Score		Results
2	A	Item A Name	11		Item E Name scored 11
3	B	Item B Name	10		Item A Name scored 11
4	C	Item C Name	10		Item C Name scored 10
5	D	Item D Name	8		Item B Name scored 10
6	E	Item E Name	11		Item D Name scored 8
7	F	Item F Name	5		Item F Name scored 5
Sheet11

Cell Formulas
Range	Formula
E2:E7	E2	=IFERROR(INDEX(B:B,MOD(AGGREGATE(14,6,C$2:C$7+ROW(C$2:C$7)/1000,ROWS(E$2:E2)),1)*1000)&" scored "&LARGE(C$2:C$7,ROWS(E$2:E2)),"")

This uses the row number to break ties, so if there is a tie, the lower entry will display first. Also, this assumes that the scores are integers. If that's not the case, then this will not work right.

 

[IteachThings]

This is perfect! Thank you so much!

 

[Eric W]

You're very welcome! Thanks for the update.