Screenshot range & save to path

[ipbr21054]

Morning.
As per title & some info for you.
Many Thanks.

Commandbutton1 will have the code
Range to screenshot is E5:F24
Path to save screenshot is C:\Users\Ian\Desktop\SCREEN SHOTS

 

[Domenic]

Try the following code, which will export the specified range to the specified folder, and save the image file as MyImage.jpg. Change the name as desired. Also, to change the file type, simply change the file extension (ie. .bmp, .gif, .jpg, or .png). So, for example, to export the image as a PNG, use MyImage.png.

Option Explicit

Sub test()

    Dim errorMessage As String
  
    If Not ExportRangeToImage(Range("E5:F24"), "C:\Users\Ian\Desktop\SCREEN SHOTS\MyImage.jpg", errorMessage) Then 'change the image filename as desired
        MsgBox errorMessage, vbCritical, "Error"
        Exit Sub
    End If
  
    MsgBox "Range has been exported successfully!", vbExclamation
  
End Sub

Public Function ExportRangeToImage(ByVal rangeToExport As Range, ByVal saveAsFileName As String, ByRef errorMessage As String) As Boolean

'export range to .bmp, .gif, .jpg, or .png image file

    On Error GoTo errorHandler
  
    rangeToExport.CopyPicture appearance:=xlScreen, Format:=xlPicture
  
    With rangeToExport.Parent.ChartObjects.Add(Left:=rangeToExport.Left, Top:=rangeToExport.Top, Width:=rangeToExport.Width + 2, Height:=rangeToExport.Height + 2)
        .Activate
        With .Chart
            .ChartArea.Format.Line.Visible = msoFalse
            .Paste
            With .Pictures(1)
                .Left = .Left + 2
                .Top = .Top + 2
            End With
            .Export fileName:=saveAsFileName
        End With
        .Delete
    End With
  
    ExportRangeToImage = True
  
    Exit Function
  
errorHandler:
    errorMessage = "Error " & Err.Number & ": " & Err.Description
    ExportRangeToImage = False

End Function

Hope this helps!

 

[ipbr21054]

Works perfect thanks

 

[Domenic]

You're very welcome, cheers!

 

[ipbr21054]

@Domenic
I have an issue with this project.
I am unable to type in the cells within the range.

My goal was to =type in each cell then at the end of the week i would screen screen shot the range & start again the next week.
What happens when i click in the range now is that i see a border around the outside of the range show up & i am unable to type or even fill the cell a different color.

 

[ipbr21054]

Well ive used it a few times today & its been fine.

It was a screensot upon the range on the sheet,not sure how but it hasnt done it since.
Thanks