Search VBA code for PDF

[Tofik]

Hi guys who can help me to create the VBA code to search PDF files for example in location (C:/New Folder 2)
I need to create excel in which I input file and have results from searching below.

AAAA15.xlsx
	A	B	C	D	E	F	G
1
2	Find:	21-PIP-ISO-08502-0006			Send to folder ( C:\New Folder 1 )	button(Active X)
3			Last date file was modified ( Date modified )
4	1	HS523217-21-PIP-ISO-08502-0006_RM01B.pdf	3/30/2022
5	2	HS523217-21-PIP-ISO-08502-0006_RM01A.pdf	3/11/2022
6	3	HS523217-21-PIP-ISO-08502-0006_2.pdf	1/13/2022
7	4	HS523217-21-PIP-ISO-08502-0006_1B.pdf	1/6/2022
8	5	HS523217-21-PIP-ISO-08502-0006_1A.pdf	10/27/2021
9	6	HS523217-21-PIP-ISO-08502-0006_1.pdf	7/12/2021
10	7
11	8
12	3
13	10
14
15
Sheet1

 

[John_w]

Try this macro. It reads the search folder path from B1, e.g. C:\New Folder 2\

Public Sub Find_PDF_Files()

    Dim folder As String, findFile As String, file As String
    Dim n As Long
    Dim destCell As Range
   
    With ActiveSheet
        folder = Trim(.Range("B1").Value)
        findFile = .Range("B2").Value
        Set destCell = .Range("A4:C4")
       
        n = .Cells(.Rows.Count, "A").End(xlUp).Row
        If n >= 4 Then destCell.Resize(n - destCell.Row + 1).ClearContents
   
        If Right(folder, 1) <> "\" Then folder = folder & "\"
        n = 0
        file = Dir(folder & "*" & findFile & "*.pdf")
        While file <> vbNullString
            destCell.Offset(n).Value = Array(n + 1, file, FileDateTime(folder & file))
            n = n + 1
            file = Dir
        Wend
       
        .Columns("C").NumberFormat = "m/d/yyyy"
    End With
   
End Sub

 

[Tofik]

Try this macro. It reads the search folder path from B1, e.g. C:\New Folder 2\

Public Sub Find_PDF_Files()

    Dim folder As String, findFile As String, file As String
    Dim n As Long
    Dim destCell As Range
 
    With ActiveSheet
        folder = Trim(.Range("B1").Value)
        findFile = .Range("B2").Value
        Set destCell = .Range("A4:C4")
     
        n = .Cells(.Rows.Count, "A").End(xlUp).Row
        If n >= 4 Then destCell.Resize(n - destCell.Row + 1).ClearContents
 
        If Right(folder, 1) <> "\" Then folder = folder & "\"
        n = 0
        file = Dir(folder & "*" & findFile & "*.pdf")
        While file <> vbNullString
            destCell.Offset(n).Value = Array(n + 1, file, FileDateTime(folder & file))
            n = n + 1
            file = Dir
        Wend
     
        .Columns("C").NumberFormat = "m/d/yyyy"
    End With
 
End Sub
[/CODEHi
[/QUOTE]

Thanks. [/B]

Hi John , thanks for your VBA code. As I understood it is only Search VBA code without special button which send needed searched document from the result list in to the folder different folder. ( Example if I have result B4 B5 B6 B7 B8 B9 after searching from folder NewFolder1(which have all scope of documents),and I want take only needed document (only B5 for example) and send the copy to the NewFolder2.

And the main Question from your VBA where I should correct and specify the path to the folder from your code ?

 

[John_w]

As I understood it is only Search VBA code without special button which send needed searched document from the result list in to the folder different folder. ( Example if I have result B4 B5 B6 B7 B8 B9 after searching from folder NewFolder1(which have all scope of documents),and I want take only needed document (only B5 for example) and send the copy to the NewFolder2.

Yes, the macro only searches the folder for the partial file name in B2 and puts the search results in A4:C4 down. You didn't say anything about copying one of the found files to another folder, which will be another macro. How do you want to specify which of the found files should be copied to the other folder? How will you specify this folder?

And the main Question from your VBA where I should correct and specify the path to the folder from your code ?

As the code is written, you should specify the folder path in cell B1. If you wish, I can change it to open a folder browser for you to choose the search folder.

 

[Tofik]

Thanks it works Perfect.