Selecting specific rows

[lshea]

I would like to select all rows in a spreadsheet where the entry in column A is blank. These rows I will then format with a different color and bold in one fail swoops.

 

[starl]

Dim rng As Range

On Error Resume Next
Set rng = ActiveSheet.Range("A1").EntireColumn.SpecialCells(xlCellTypeBlanks)
On Error GoTo 0

If Not rng Is Nothing Then
    rng.EntireRow.Font.Bold = True
   'what other formatting you want
End If

 

[lshea]

Huge learning curve on my part. I read Help on how to see the Developer Tab visible. I copied/pasted your macro code. I searched help on how to select red font.
I'm getting an error that I don't understand. The line "On Error Resume Next" is highlighted and the error message says "Compile error: Invalid outside procedure."
I read something about you have to do something to your file to allows for macros?

 

[starl]

Workbooks have to be xls or xlsm to allow for macro. Then you have to be sure to Enable Macros when you open a workbook with macros.

But your current issue is that I didn't put the code in a procedure.
Copy/paste the following:

Sub SelectBlanksinColumnA()
'works on the ACTIVE sheet
Dim rng As Range

On Error Resume Next
Set rng = ActiveSheet.Range("A1").EntireColumn.SpecialCells(xlCellTypeBlanks)
On Error GoTo 0

If Not rng Is Nothing Then
    With rng.EntireRow.Font
        .Bold = True
        .Color = -16776961 'red
    End With
End If
End Sub

'If you don't want to color the entire row
'Then change the With above to this
'the 3 meaning the first 3 columns starting at column A
'So columns A:C would be bold and red
'
'With rng.Resize(, 3)

 

[lshea]

Perfect! Works like a charm!

 

[starl]

clarification - if you don't want the entire row, use the following to select # of columns (including column A)

With rng.Resize(, 3).Font

it would replace the original With statement