Send messages through whatsapp

[phiero21]

Hi, I am using the below script to send messages via whatsapp to different numbers. It works perfectly and sends messages in col F to all numbers.

However, I want to modify the script to send 3 messsages to the numbers. The messages are in col F, G & H. Any suggestions please

Sub Send_Text_To_WhatsApp()

Dim whatsapp_number As String


Dim sh As Worksheet
Set sh = ThisWorkbook.Sheets("Data")

Dim i As Integer

For i = 4 To sh.Range("A" & Application.Rows.Count).End(xlUp).Row

If sh.Range("J" & i).Value <> "Yes" Then   '' Check Skip

        whatsapp_number = sh.Range("I" & i).Value
    
        ThisWorkbook.FollowHyperlink "https://web.whatsapp.com/send?phone=%2B" & whatsapp_number & "&text=" & _
        sh.Range("F" & i).Value & "&app_absent=1&send=1"
      
        Application.Wait (Now() + TimeValue("00:00:08"))

            VBA.SendKeys "~", True
            
            
            
            Application.Wait (Now() + TimeValue("00:00:01"))
            
             
    End If

Next i

MsgBox "Process Completed", vbInformation

End Sub

 

[FormR]

Hi, you could try adding another, inner loop, something like this:

Sub Send_Text_To_WhatsApp()

Dim whatsapp_number As String


Dim sh As Worksheet
Set sh = ThisWorkbook.Sheets("Data")

Dim i As Long, j As Long

For i = 4 To sh.Range("A" & Application.Rows.Count).End(xlUp).Row

If sh.Range("J" & i).Value <> "Yes" Then   '' Check Skip

        whatsapp_number = sh.Range("I" & i).Value
    
        For j = 0 To 2
    
            ThisWorkbook.FollowHyperlink "https://web.whatsapp.com/send?phone=%2B" & whatsapp_number & "&text=" & _
            sh.Range("F" & i).Offset(, j).Value & "&app_absent=1&send=1"
          
            Application.Wait (Now() + TimeValue("00:00:08"))
    
            VBA.SendKeys "~", True
                
            Application.Wait (Now() + TimeValue("00:00:01"))
            
        Next j
                     
                     
    End If

Next i

MsgBox "Process Completed", vbInformation

End Sub