Show cell contents on click

[_saiko]

Using a basic white color method to hide cell values I can successfully use this code to show (change color to black) the text inside a cell:

Private Sub Worksheet_SelectionChange(ByVal Target As Range)

If Target.Font.ColorIndex = 2 Then
    Target.Font.ColorIndex = 1
End If
End Sub

Now i wonder how to "restore" white color back for the cell contents after deselect?


Also is it possible to change the text color to white (or to replace the text with something else) immediately after the input?

 

[mikerickson]

How about this

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    Static lastRange As Range
    
    If lastRange Is Nothing Then
        UsedRange.Font.ColorIndex = 2
    Else
        lastRange.Font.ColorIndex = 2
    End If
    Set lastRange = Target
    
    Target.Font.ColorIndex = xlAutomatic
End Sub

 

[mikerickson]

This will restrict its action to a specified range.

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    Const CLWht As Long = 2
    Static lastRange As Range
    Dim actionRange As Range
    Set actionRange = Range("A1:D5"): Rem adjust
    
    If lastRange Is Nothing Then
        actionRange.Font.ColorIndex = CLWht
    Else
        On Error Resume Next
        Application.Intersect(actionRange, lastRange).Font.ColorIndex = CLWht
        On Error GoTo 0
    End If
    
    Set lastRange = Target
    
    On Error Resume Next
    Application.Intersect(actionRange, Target).Font.ColorIndex = xlAutomatic
    On Error GoTo 0
End Sub

 

[_saiko]

Thanks works like a charm!