SPOT THE DIFFERENCE! Working with IF...

[spacebouncer]

Hi! Can you help?! I thought I was getting the hang of things, perhaps I'm tired!

I've written a little code just to toggle a box between two states. The first code I tried didn't work, the second does. It would be a great if anyone could explain why the first routine doesn't work. Thanks

'''''''''''''''''''''''''''''''''''''''''''''''''
''''               Recommend HW routines
'''''''''''''''''''''''''''''''''''''''''''''''''

Sub recommendhw1()
'TODO will set a HW task
'Currently toggles between the two states

Dim selectedshape As Shape
Set selectedshape = Sheets("Seating Plans").Shapes(Application.Caller)

If selectedshape.TextFrame.Characters.Text = "Recommend Task" Then
    With selectedshape
        .TextFrame.Characters.Text = "Task Recommended"
        .Fill.ForeColor.RGB = RGB(119, 147, 60)
    End With
End If

If selectedshape.TextFrame.Characters.Text = "Task Recommended" Then
    With selectedshape
            .TextFrame.Characters.Text = "Recommend Task"
            .Fill.ForeColor.RGB = RGB(128, 100, 162)
    End With
End If

End Sub


Sub recommendmyhw1()
'TODO will set a HW task
'Currently toggles between the two states

Dim selectedshape As Shape
Set selectedshape = Sheets("Seating Plans").Shapes(Application.Caller)

If selectedshape.TextFrame.Characters.Text = "Recommend Task" Then
    With selectedshape
        .TextFrame.Characters.Text = "Task Recommended"
        .Fill.ForeColor.RGB = RGB(119, 147, 60)
    End With
Else
    If selectedshape.TextFrame.Characters.Text = "Task Recommended" Then
        With selectedshape
            .TextFrame.Characters.Text = "Recommend Task"
            .Fill.ForeColor.RGB = RGB(128, 100, 162)
        End With
    Else: Exit Sub
    End If
End If

End Sub

 

[Taul]

just before "If selectedshape"
first code uses "End If"
second code uses "Else"

 

[pgc01]

Hi

In the second code you have If ... Else ... Endif.

This means that the code will never execute both branches of the If.

Either it executes the first branch or the second.


In the first code you have 2 If's in sequence. This means that the code can execute both, if both conditions match.

This is the case when the Shape text is

"Recommend Task"

In this case the first conditions is met, because the text is "Recommend Task". The code will change the text to "Task Recommended".
Then it will execute the second If, because the text is "Task Recommended". The code will change the text again back to "Recommend Task".


In conclusion, if the shape text at the beginning is "Recommend Task"
- in the first code both If's code are executed
- in the second code only one of the outer If's is executed
</pre>

 

[spacebouncer]

Good spot Taul!

Thanks pgc, I couldn't see that for the life of me last night! I thought for a moment everything I thought I knew about coding was in doubt!