Strange listbox problem

[Glory]

I’ve created a listbox. I’ve added one item to that listbox.

The listcount property = 1, but looping through each item in the list executes ten cycles instead of one (I’ve used a message box to confirm this).<?xml:namespace prefix = o ns = "urn:schemas-microsoft-comfficeffice" /><o></o>
<o> </o>
How can this be?

 

[GlennUK]

Show all of your code, for a start.

 

[Glory]

'Two userforms.
'1) Contains a textbox
'2) Contains one listbox

'Userform1:

Private Sub commandbutton1_click()
job = TextBox1
If Not Join(r) = "" Then
For Each thing In r()
If thing = job Then
JobPresent = MsgBox("Redundant entry.", vbOKOnly, "Redundant Entry")
Exit Sub
End If
Next
End If
If IsEmpty(x) Then
p = p + 1
ReDim Preserve r(1 To p)
r(p) = job
'MsgBox Join(r, Chr(10))
Else
x = x + 1
ReDim Preserve r(1 To x)
r(x) = job
'MsgBox Join(r, Chr(10))
End If
End Sub

'UserForm 2:

Private Sub UserForm_Initialize()
'==================================================
'used to fill the listbox from the array r()
If Join(r) = "" Then
    MsgBox "Join(r) = """""
    Exit Sub
End If
For Each element In r()
    v = v + 1
'    If Not IsEmpty(element) Then
        ListBox1.AddItem r(v)
'    End If
Next
'==================================================
'Purely for test
For Each thing In ListBox1.List
asd = asd + 1
Next
For Each thing In r()
asdf = asdf + 1
Next
MsgBox "ListBox1.ListCount = " & asd & Chr(10) & "Array r() = " & asdf & elements
'==================================================
End Sub

'Standard Module:

Public r()
Public Sub test9999()
UserForm1.Show
End Sub

 

[Glory]

Start by entering some text in the ugly textbox, click the big command button on the top, then click the little one on the bottom.<?xml:namespace prefix = o ns = "urn:schemas-microsoft-comfficeffice" /><o></o>
<o> </o>
The second form loads and appears. A messagebox appears which reveals the listbox count and the number of elements in r().<o></o>
<o> </o>
r() contains 1 element, and the listboxcount is 10 for some weird reason.<o></o>
<o> </o>
Any ideas?<o></o>

 

[GlennUK]

Why don't you clear the listbox before you start adding items to it?

 

[Glory]

Hence the other thread you responded to last night.

I've already tried doing that, using the method you posted in that other thread (Clear). It doesn't solve the problem.

There are still ten items in the listbox list, even though the code explicitly adds only non-empty elements from the array, and the array contains just one element if you press commandbutton1 a single time.

Did you work at all with the example I posted? I'm able to reproduce this apparent bug without issue.

 

[AlphaFrog]

It appears that the default array size of the .List for a ListBox is a zero based array of (0, 9) for each item added to the list. That is...
one item added: .List array = 0,9
two items added: .List array = 1,9
three items added: .List array = 2,9

Why it has a 2nd dimension default to 10 elements, I don't know. There's probably a reason (maybe legacy).

So when you use...
For Each thing In ListBox1.List
... that will loop through all 10 elements (zero to 9) for each entry in the .List.
Doesn't matter if you filled all 10 elements or not.

You could use this instead...

[COLOR="Green"]'Purely for test[/COLOR]
For i = 0 to ListBox1.ListCount - 1
asd = asd + 1
Next i

This is the test I used...

Private Sub UserForm_Initialize()

    n = 5

    With ListBox1
    
    'Add items to list
    For i = 1 To n
        .AddItem "Item " & i
    Next i
    
        For i = 0 To .ListCount - 1     ' Count items
            asd = asd + 1
        Next i
        For Each element In .List       ' Count elements
            elCount = elCount + 1
        Next element
        
    MsgBox ".List array size = " & UBound(.List, 1) & "," & UBound(.List, 2) & vbCr & _
           ".List total number of elements = " & elCount & vbCr & _
           ".ListCount property = " & .ListCount & vbCr & _
           ".List counted by loop = " & asd, _
           Title:=n & " Items Added"

    End With

End Sub