SUMIF Returning #VALUE!

[bigbraincantoo03]

I have a SUMIF formula in cell B21 that is supposed to add up some reference cells in a different tab, but gives me a #VALUE! instead. The cells it is supposed to add in the different tab based are supposed to be within the date range specified in cells B4 and B5. I'm not sure if this has anything to do with the fact that B4 is an array formula or not, but I thought this might have something to do with it. Any help is appreciated.

Grafica de Avance - V4.0.xlsx
	A	B
3	Report Month	Aug
4	Start Date:	24-Aug-20 15:30
5	End Date:	01-Sep-20 00:00
6	Rig Name	Plataforma
7	Well name / Sites	Ejemplo
20	Total Operating Hours (Hours)	176
21	Drilling Phase or on-bottom drilling (Hours)	#VALUE!
22	NPT (Hours )
23	High Impact Incidents/ HIF (count)
24	P50 or Budget OTD: Days Ahead (-) / Behind (+) of Plan (Days)
25	P80 or Target OTD: Days Ahead (-) / Behind (+) of Plan (Days)
26	OTD benchmark, P50/Budget (Days)
27	OTD benchmark, P80/Target (Days) - if applicable
28	Actual days in progress (Days)	11.7
29	Wells drilled, reached TD (Count)
30	{Jobs/stages completed} (Count) - if applicable
31	{Project rig count or frac fleet} (Count)
32	Distance drilled (ft)	#VALUE!
PM Info

Cell Formulas
Range	Formula
B4	B4	=MIN(IF(SIOP!$F$6:$F$1720>(1&B3)+0,SIOP!$F$6:$F$1720))
B5	B5	=MIN(MAX(SIOP!$G$6:$G$1720),EDATE(--(1&B3),1))
B6	B6	='Well Program'!$K$2
B7	B7	='Well Program'!$G$2
B20	B20	=IF(B3=0,"",(B5-B4)*24)
B21	B21	=SUMIFS(SIOP!$H$5:$H$1720,SIOP!$F$6:$F$1720,">="&$B4,SIOP!$G$6:$G$1720,"<="&$B5,SIOP!$O$5:$O$1720,$FX$4)/24
B28	B28	=MAX(SIOP!$AA$4:$AA$1750)
B32	B32	=IF(B5>0,(SUMIFS(SIOP!$AH$4:$AH$1720,SIOP!$X$4:$X$1720,"BKR",SIOP!$F$6:$F$1720,">"&B4,SIOP!$G$6:$G$1720,"<"&B5))/24,"")
Press CTRL+SHIFT+ENTER to enter array formulas.

Cells with Data Validation
Cell	Allow	Criteria
B3:T3	List	=Month

 

[Peter_SSs]

Your ranges in that formula are not all the same size

=SUMIFS(SIOP!$H$5:$H$1720,SIOP!$F$6:$F$1720,">="&$B4,SIOP!$G$6:$G$1720,"<="&$B5,SIOP!$O$5:$O$1720,$FX$4)/24

 

[bigbraincantoo03]

Your ranges in that formula are not all the same size

=SUMIFS(SIOP!$H$5:$H$1720,SIOP!$F$6:$F$1720,">="&$B4,SIOP!$G$6:$G$1720,"<="&$B5,SIOP!$O$5:$O$1720,$FX$4)/24

Well I feel dumb now. Thanks for the help Peter_SSs

 

[Peter_SSs]

Never mind, that happens sometimes. ?
You're welcome.