swap text left side of comma with text right side of comma

[IvoOvermars]

Goedmorning,

Someone gave me a two list of names I have to compare. However the names differ in the way they are set up. Now i would like to switch the text left of the comma with the text right of the comma. Is this possible?

Example

List 1

Velde, van der Same name in list 2 van der Velde Kind regards, Ivo

<tbody>
</tbody>

 

[Rick Rothstein]

Give this formula a try...

=MID(A1&" "&A1,FIND(" ",A1)+1,LEN(A1)-1)

 

[VoG]

Try

=RIGHT(A1,LEN(A1)-FIND(",",A1)-1)&" "&LEFT(A1,FIND(",",A1)-1)

 

[IvoOvermars]

Hang on having this annoying dutch version with also translates the formulas :s. Figuring out what dutch formula to use

 

[VoG]

Look heree http://www.mrexcel.com/forum/questions-other-languages/462498-worksheet-function-translations.html

and replace , with ;

 

[IvoOvermars]

Not sure why yet. But I get an error on the underlined part

RECHTS(A1,LENGTE(A1)-VIND(",",A1)-1)&" "&LINKS(A1,VIND(",",A1)-1)

 

[VoG]

Probably should be

RECHTS(A1;LENGTE(A1)-VIND(",",A1)-1)&" "&LINKS(A1;VIND(",",A1)-1)

 

[IvoOvermars]

Thank you got it to work. I had to replace the one word formula FIND with VIND.ALLES. Wich translated means Find.ALL

=RECHTS(A1;LENGTE(A1)-VIND.ALLES(",";A1)-1)&" "&LINKS(A1;VIND.ALLES(",";A1)-1)

 

[Rick Rothstein]

Based on the link VoG posted, I believe the formula I posted in Message #2 translates this way...

=DEEL(A1&" "&A1;VIND(" ";A1)+1;LENGTE(A1)-1)



EDIT NOTE: Or, based on what you posted in Message #8, possibly this....

=DEEL(A1&" "&A1;VIND.ALLES(" ";A1)+1;LENGTE(A1)-1)

 

[IvoOvermars]

Yes, that last one also works .

Thank you both, enjoy your weekend