Too many line continuations

[techstyle20]

Good Morning,

I was wondering whether anyone could tell me how to add more "Or" statments to the following?

I get the message "Too many line continuations". Is there a more elegant way of testing each of the cells without having to include a new row for each?

Thanks guys,

T.

'Please Selects
If Worksheets("Additional Conditions").Range("F8") <> "- Please Select -" _
Or Worksheets("Additional Conditions").Range("F11") <> "- Please Select -" _
Or Worksheets("Additional Conditions").Range("F14") <> "- Please Select -" _
Or Worksheets("Additional Conditions").Range("F17") <> "- Please Select -" _
Or Worksheets("Additional Conditions").Range("F20") <> "- Please Select -" _
Or Worksheets("Additional Conditions").Range("F43") <> "- Please Select -" _
Or Worksheets("Additional Conditions").Range("F46") <> "- Please Select -" _
Or Worksheets("Additional Conditions").Range("F49") <> "- Please Select -" _
Or Worksheets("Additional Conditions").Range("F52") <> "- Please Select -" _
Or Worksheets("Additional Conditions").Range("F55") <> "- Please Select -" _
Then
Worksheets("Offer Letter Instruction Sheet").Range("P15") = "Additional Conditions"
Else
Worksheets("Offer Letter Instruction Sheet").Range("P15") = ""
End If

 

[JackDanIce]

See if this works better:

Dim cell As range
With Worksheets("Additional Conditions")
For Each cell In .range("F8", "F11", "F14", "F17", "F20", "F43", "F46", "F49", _
    "F52", "F55")
    Worksheets("Offer Letter Instruction Sheet").range("P15").ClearContents 
    If cell.Value <> "- Please Select -" Then _
        Worksheets("Offer Letter Instruction Sheet").range("P15") = "Additional Conditions"
Next Cell

 

[techstyle20]

Thanks Jack,

Thats looks much simpler however I am getting a compile error "Expected End With"?

T.

 

[JackDanIce]

Because I forgot a line! Try:

Dim cell As range
With Worksheets("Additional Conditions")
  For Each cell In .range("F8", "F11", "F14", "F17", "F20", "F43", "F46", "F49", _
    "F52", "F55")
    Worksheets("Offer Letter Instruction Sheet").range("P15").ClearContents 
    If cell.Value <> "- Please Select -" Then _
        Worksheets("Offer Letter Instruction Sheet").range("P15") = "Additional Conditions"
  Next Cell
End With

 

[RoryA]

I think you may want an Exit For before the Next Cell line.

 

[Peter_SSs]

Because I forgot a line!

And to test?
I think this code has a couple of problems.
1. The range syntax is incorrect.

2. It will populate P15 on the 'Offer' sheet based only on the basis of the final cell in the given range in in the 'Additional Conditions' sheet. My interpretation of the original code is that P15 should only be cleared if every cell in the given range contains "- Please Select -". If so, consider this code

Sub Test1()
  Dim c As Range
  Dim AddCond As Boolean
  
  Const myCells As String = "F8, F11, F14, F17, F20, " & _
                            "F43, F46, F49, F52, F55"         '<-Can add more here
                            
  For Each c In Worksheets("Additional Conditions").Range(myCells)
    If c.Value <> "- Please Select -" Then AddCond = True
  Next c
  Worksheets("Offer Letter Instruction Sheet").Range("P15").Value _
    = IIf(AddCond, "Additional Conditions", "")
End Sub

 

[JackDanIce]

Good spot Rory and Peter, I think then mine should be:

Dim cell As range
With Worksheets("Additional Conditions")
  For Each cell In .range("F8, F11, F14, F17, F20, F43, F46, F49, _
    F52, F55")
    Worksheets("Offer Letter Instruction Sheet").range("P15").ClearContents 
    If cell.Value <> "- Please Select -" Then
        Worksheets("Offer Letter Instruction Sheet").range("P15") = "Additional Conditions"
        Exit For
    End If
  Next Cell
End With

As Peter's suggestion shows, a few different approaches to this too

 

[techstyle20]

Hi Jack,

Unfortunately this comes up with "Runtime error 450"

"Wrong number of arguments or invalid property assignment"

Could this be a problem with some other part of my code?

T.

 

[techstyle20]

Thanks guys,

I tried Peters code there and it works perfectly!

This is a great help for future projects also.

Thanks to you all!

T.

 

[Peter_SSs]

Deleted