Transpose and Summarize the data using VBA

[kumark1]

Hi All,

I got a project Requirement where i need to Transpose nad summarize the data, I tried doing it in Pivot, i could not get the output.
Can this be done thru the VBA


Output

Risk/Complexity	Easy <tbody> </tbody>	Medium <tbody> </tbody>	Difficult <tbody> </tbody>
High <tbody> </tbody>	Project1_Project4 <tbody> </tbody>	Project3 <tbody> </tbody>
Low <tbody> </tbody>	Project5 <tbody> </tbody>		Project2_Project6 <tbody> </tbody>
Moderate <tbody> </tbody>		Project9 <tbody> </tbody>	Project7_Project8 <tbody> </tbody>

<tbody>
</tbody>

Input

Project	Complex	Risk
Project 1	Easy	High
Project 2	difficult	Low
Project 3	Medium	High
Project 4	Easy	High
Project 5	Easy	Low
Project 6	difficult	Low
Project 7	difficult	Moderate
Project 8	difficult	Moderate
Project 9	Medium	Moderate

<tbody>
</tbody>

 

[hiker95]

kumark1,

Here is a macro solution for you to consider that is based on your flat text displays.

I assume that Input, and, Output, are worksheets that already exist.

Sample raw data worksheets:

Excel 2007
	A	B	C
1	Project	Complex	Risk
2	Project 1	Easy	High
3	Project 2	difficult	Low
4	Project 3	Medium	High
5	Project 4	Easy	High
6	Project 5	Easy	Low
7	Project 6	difficult	Low
8	Project 7	difficult	Moderate
9	Project 8	difficult	Moderate
10	Project 9	Medium	Moderate
11
Input

Excel 2007
	A	B	C	D
1	Risk/Complexity	Easy	Medium	Difficult
2	High
3	Low
4	Moderate
5
Output

And, after the macro in worksheet Output:

Excel 2007
	A	B	C	D
1	Risk/Complexity	Easy	Medium	Difficult
2	High	Project 1_Project 4	Project 3
3	Low	Project 5		Project 2_Project 6
4	Moderate		Project 9	Project 7_Project 8
5
Output

Please TEST this FIRST in a COPY of your workbook (always make a backup copy before trying new code, you never know what you might lose).

1. Copy the below code
2. Open your NEW workbook
3. Press the keys ALT + F11 to open the Visual Basic Editor
4. Press the keys ALT + I to activate the Insert menu
5. Press M to insert a Standard Module
6. Where the cursor is flashing, paste the code
7. Press the keys ALT + Q to exit the Editor, and return to Excel
8. To run the macro from Excel press ALT + F8 to display the Run Macro Dialog. Double Click the macro's name to Run it.

Option Compare Text
Sub ReorgData()
' hiker95, 04/06/2016, ME932716
Dim wi As Worksheet, wo As Worksheet
Dim c As Range
Dim h As Range, l As Range, m As Range
Dim emd As Range
Application.ScreenUpdating = False
Set wi = Sheets("Input")
Set wo = Sheets("Output")
With wi
  For Each c In .Range("C2", .Range("C" & Rows.Count).End(xlUp))
    Set h = wo.Columns(1).Find(c.Value, LookAt:=xlWhole)
    Set emd = wo.Rows(1).Find(c.Offset(, -1).Value, LookAt:=xlWhole)
    If (Not h Is Nothing) * (Not emd Is Nothing) Then
      If wo.Cells(h.Row, emd.Column) = vbEmpty Then
        wo.Cells(h.Row, emd.Column).Value = c.Offset(, -2).Value
      Else
        wo.Cells(h.Row, emd.Column).Value = wo.Cells(h.Row, emd.Column).Value & "_" & c.Offset(, -2).Value
      End If
    End If
  Next c
End With
With wo
  .Columns(1).Resize(, 4).AutoFit
  .Activate
End With
Application.ScreenUpdating = True
End Sub

Before you use the macro with Excel 2007 or newer, save your workbook, Save As, a macro enabled workbook with the file extension .xlsm, and, answer the "do you want to enable macros" question as "yes" or "OK" (depending on the button label for your version of Excel) the next time you open your workbook.

Then run the ReorgData macro.