Transpose Data

[VinodKrishnappa]

Hi Can any one help me on this transpose the available following data in a particular format. This data will continue for more than 650 rows & 26 columns

Emp. No.	Name	Comp1	Comp2	Comp3	Comp4	Comp5	Comp8	Comp9
2002	A	2000	800	1600	2500	12500	0	1500
2003	B	2200	880	1600	2500	12500	0	1500
2004	C	2400	960	1600	2500	12000	200	1500

<colgroup><col><col><col span="7"></colgroup><tbody>
</tbody>

Note: Any Comp with 0 value to be ignored in the transposed data.

Format for transpose

Comps	Amt.	Emp. ID
Comp1	2000	2002
Comp2	800	2002
Comp3	1600	2002
Comp4	2500	2002
Comp5	12500	2002
Comp9	1500	2002
Comp1	2200	2003
Comp2	880	2003
Comp3	1600	2003
Comp4	2500	2003
Comp5	12500	2003
Comp9	1500	2003
Comp1	2400	2004
Comp2	960	2004
Comp3	1600	2004
Comp4	2500	2004
Comp5	12000	2004
Comp8	200	2004
Comp9	1500	2004

<colgroup><col span="3"></colgroup><tbody>
</tbody>

Please help me on this.

Thanks in advance.

 

[steve the fish]

Could do it with VBA.

Set initialsh = Sheets("Sheet1")
Set transposesh = Sheets("Sheet2")
lr = initialsh.Cells(Rows.Count, 1).End(xlUp).Row
lc = initialsh.Cells(1, Columns.Count).End(xlToLeft).Column
If lr < 2 Or lc < 3 Then Exit Sub
With transposesh
    .Cells.ClearContents
    .Range("A1") = "Comps"
    .Range("B1") = "Amt."
    .Range("C1") = "Emp.ID"
End With
firstrow = 2
For i = 2 To lr
    Range(initialsh.Cells(1, 3), initialsh.Cells(1, lc)).Copy
    transposesh.Cells(firstrow, 1).PasteSpecial Paste:=xlPasteValues, Transpose:=True
    Range(initialsh.Cells(i, 3), initialsh.Cells(i, lc)).Copy
    transposesh.Cells(firstrow, 2).PasteSpecial Paste:=xlPasteValues, Transpose:=True
    Range(transposesh.Cells(firstrow, 3), transposesh.Cells(firstrow + lc - 3, 3)) = initialsh.Cells(i, 1)
    firstrow = firstrow + lc - 2
Next

Assumes your first table starts in A1. Sheet names will need changing to suit.

 

[hiker95]

VinodKrishnappa,

Here is another macro solution for you to consider that uses two arrays in memory that will adjust to the number of raw data rows, and, columns, and, should be much faster then copying and pasting.

You can change the raw data worksheet name in the macro.

The macro will create a new worksheet Results.

Sample raw data:

Excel 2007
	A	B	C	D	E	F	G	H	I	J
1	Emp. No.	Name	Comp1	Comp2	Comp3	Comp4	Comp5	Comp8	Comp9
2	2002	A	2000	800	1600	2500	12500	0	1500
3	2003	B	2200	880	1600	2500	12500	0	1500
4	2004	C	2400	960	1600	2500	12000	200	1500
5
Sheet1

And, after the macro in a new worksheet Results:

Excel 2007
	A	B	C
1	Comps	Amt.	Emp. ID
2	Comp1	2000	2002
3	Comp2	800	2002
4	Comp3	1600	2002
5	Comp4	2500	2002
6	Comp5	12500	2002
7	Comp9	1500	2002
8	Comp1	2200	2003
9	Comp2	880	2003
10	Comp3	1600	2003
11	Comp4	2500	2003
12	Comp5	12500	2003
13	Comp9	1500	2003
14	Comp1	2400	2004
15	Comp2	960	2004
16	Comp3	1600	2004
17	Comp4	2500	2004
18	Comp5	12000	2004
19	Comp8	200	2004
20	Comp9	1500	2004
21
Results

Please TEST this FIRST in a COPY of your workbook (always make a backup copy before trying new code, you never know what you might lose).

1. Copy the below code
2. Open your NEW workbook
3. Press the keys ALT + F11 to open the Visual Basic Editor
4. Press the keys ALT + I to activate the Insert menu
5. Press M to insert a Standard Module
6. Where the cursor is flashing, paste the code
7. Press the keys ALT + Q to exit the Editor, and return to Excel
8. To run the macro from Excel press ALT + F8 to display the Run Macro Dialog. Double Click the macro's name to Run it.

Sub TransposeData()
' hiker95, 09/16/2016, ME965091
Dim w1 As Worksheet, wr As Worksheet
Dim a As Variant, i As Long, c As Long
Dim o As Variant, j As Long
Application.ScreenUpdating = False
Set w1 = Sheets("Sheet1")   '<-- you can change the sheet name here
a = w1.Cells(1, 1).CurrentRegion
ReDim o(1 To (UBound(a, 2) - 2) * (UBound(a, 1) - 1), 1 To 3)
For i = 2 To UBound(a, 1)
  For c = 3 To UBound(a, 2)
    If Not a(i, c) = 0 Then
      j = j + 1
      o(j, 1) = a(1, c)
      o(j, 2) = a(i, c)
      o(j, 3) = a(i, 1)
    End If
  Next c
Next i
If Not Evaluate("ISREF(Results!A1)") Then Worksheets.Add(After:=w1).Name = "Results"
Set wr = Sheets("Results")
With wr
  .UsedRange.Clear
  .Cells(1, 1).Resize(, 3).Value = Array("Comps", "Amt.", "Emp. ID")
  .Cells(2, 1).Resize(UBound(o, 1), UBound(o, 2)) = o
  .Columns(1).Resize(, UBound(o, 2)).AutoFit
  .Activate
End With
Application.ScreenUpdating = True
End Sub

Before you use the macro with Excel 2007 or newer, save your workbook, Save As, a macro enabled workbook with the file extension .xlsm, and, answer the "do you want to enable macros" question as "yes" or "OK" (depending on the button label for your version of Excel) the next time you open your workbook.

Then run the TransposeData macro.

 

[gosselien]

Hello

try this , first data in cell A2 in sheet1 !

https://we.tl/jvvDB8HBG1

Patrick