Trying to enter 3 lines in a body of an email before I paste an image

[JiggersBass]

Sub Email()
'Copy range of interest
Dim r As Range
Set r = Range("a1:g20")
r.Copy

'Open a new mail item
Set outlookApp = CreateObject("Outlook.Application")
Set outMail = outlookApp.CreateItem(olMailItem)
strbody = "Hi there" & vbNewLine & vbNewLine & _
"This is line 1" & vbNewLine & _
"This is line 2" & vbNewLine & _
"This is line 3" & vbNewLine & _
"This is line 4"

With outMail
.to = Range("a22")
.cc = Range("a23")
.Subject = Range("a24")
End With

'Get its Word editor
outMail.Display
Set wordDoc = outMail.GetInspector.WordEditor
wordDoc.Range.PasteAndFormat wdChartPicture

'To paste as a table
'wordDoc.Range.PasteExcelTable LinkedToExcel:=False, WordFormatting:=False, RTF:=False

End Sub

 

[Domenic]

Try the following code. You'll notice that I have used late binding for both libraries, Outlook and Word, for consistency.

Sub Email()

    'Copy range of interest
    Dim r As Range
    Set r = Range("a1:g20")
    r.Copy
    
    'Create an instance of Outlook
    Dim outlookApp As Object
    Set outlookApp = CreateObject("Outlook.Application")
    
    'Create an email
    Dim outMail As Object
    Set outMail = outlookApp.CreateItem(0) 'olMailItem
    
    Dim strBody As String
    strBody = "Hi there" & vbNewLine & vbNewLine & _
    "This is line 1" & vbNewLine & _
    "This is line 2" & vbNewLine & _
    "This is line 3" & vbNewLine & _
    "This is line 4"
    
    With outMail
        .display
        .to = Range("a22").Value
        .cc = Range("a23").Value
        .Subject = Range("a24").Value
        .body = strBody
        Dim wordDoc As Object
        Set wordDoc = .GetInspector.WordEditor
    End With
    
    With wordDoc
        .Application.Selection.EndKey Unit:=6 'wdStory
        .Application.Selection.TypeParagraph
        .Application.Selection.TypeParagraph
        .Application.Selection.PasteAndFormat 13 'wdChartPicture
    End With

End Sub

Hope this helps!

 

[JiggersBass]

Thank you so much, this has helped a lot!

 

[JiggersBass]

Is there a way that we can indent pasted image and call the signature as well?