Two Variant with inputbox

[Leviathan87]

I am applying a small part of my code!I have a code with two variable Value1 and Value2 and input box. I want if input number 1 or number 2 the code show me Value1 or if i press number 2 show me Value2

Sub Inputbox()
Dim Name As String
Dim LastRow As Long
Dim Value1 As String
Dim Value2 As String
Value1 = 807063
Value2 = 807059
Name = Application.InputBox("Please Select 1 To 2" & vbLf & vbLf & "1 - 807063 - " & vbLf & "2 - 807059 ", "Enter a value")
If Name = TRUE Then
LastRow = Cells(Rows.Count, "C").End(xlUp).Row + 1
lastRow = lastRow = Cells(Rows.Count, "C").End(xlUp).Row + 1
Range("C" & LastRow).Value = Value1
Else: Value2 = LastRow = Cells(Rows.Count, "C").End(xlUp).Row + 1
lastRow1 = lastRow1 = Cells(Rows.Count, "C").End(xlUp).Row + 1
Range("C" & LastRow).Value = Value2
End If
Exit Sub

 

[Domenic]

Try . . .

Sub Inputbox()

    Dim UserChoice As Variant
    Dim NextRow As Long
    Dim Value1 As String
    Dim Value2 As String
    
    Value1 = 807063
    Value2 = 807059
    
    Do
        UserChoice = Application.Inputbox("Please Select 1 To 2" & vbLf & vbLf & "1 - 807063 - " & vbLf & "2 - 807059 ", "Enter a value", Type:=1)
        If UserChoice = False Then Exit Sub
        If UserChoice = 1 Or UserChoice = 2 Then Exit Do
        MsgBox "Number is invalid.", vbExclamation
    Loop
    
    NextRow = Cells(Rows.Count, "C").End(xlUp).Row + 1
    
    If UserChoice = 1 Then
        Range("C" & NextRow).Value = Value1
    ElseIf UserChoice = 2 Then
        Range("C" & NextRow).Value = Value2
    End If
    
End Sub

Hope this helps!

 

[Joe4]

One other thing:

You should NEVER use reserved words like "Inputbox" as the name of your procedures, functions, or variables!
Doing so can cause errors and unexpected results (when you try to call "Inputbox", Excel may have trouble figuring out whether you mean your procedure or the built-in InputBox).

 

[Leviathan87]

Many thanks! That works very well!!!

 

[Domenic]

You're very welcome, glad we could help.

Cheers!