UDF array function with two columns not next to eachother?

[VBE313]

In the following function, I want to get every column that says "Y" and sum everything until the next "Y". My function works properly. However, What if column B was not next to column A? How can I get the range with two columns that are not connected?

Function getY(rng As Range)
    Dim i As Integer, j As Integer, n As Integer
    Dim temp As Integer, A(), ret()
    n = rng.Rows.Count
    ReDim ret(1 To n, 0)
    A = rng
    For j = 1 To n
        If A(j, 2) = "Y" Then
            ret(j, 0) = A(j, 1)
            i = 0
        Else
            i = i + 1
            ret(j - i, 0) = ret(j - i, 0) + A(j, 1)
        End If
    Next j
    getY = ret
End Function

Here is an example of what I need to accomplish (i know this doesn't work)

 

[Fluff]

How about

Function getY(Rng1 As Range, Rng2 As Range) As Variant
    Dim i As Integer, j As Integer, n As Integer
    Dim A As Variant, B As Variant, ret()
    n = Rng1.Rows.Count
    ReDim ret(1 To n, 0)
    A = Rng1.Value2
    B = Rng2.Value2
    For j = 1 To n
        If B(j, 2) = "Y" Then
            ret(j, 0) = A(j, 1)
            i = 0
        Else
            i = i + 1
            ret(j - i, 0) = ret(j - i, 0) + A(j, 1)
        End If
    Next j
    getY = ret
End Function

 

[VBE313]

How about

Function getY(Rng1 As Range, Rng2 As Range) As Variant
    Dim i As Integer, j As Integer, n As Integer
    Dim A As Variant, B As Variant, ret()
    n = Rng1.Rows.Count
    ReDim ret(1 To n, 0)
    A = Rng1.Value2
    B = Rng2.Value2
    For j = 1 To n
        If B(j, 2) = "Y" Then
            ret(j, 0) = A(j, 1)
            i = 0
        Else
            i = i + 1
            ret(j - i, 0) = ret(j - i, 0) + A(j, 1)
        End If
    Next j
    getY = ret
End Function

Hi Fluff, I am getting a #VALUE! when trying. I entered "=getY(A1:A33,C1:C33)" Am i typing that in wrong?

 

[Fluff]

Oops, should be

If B(j, 1) = "Y" Then

 

[VBE313]

Oops, should be

If B(j, 1) = "Y" Then

Worked perfect! Thank you Fluff!

 

[Fluff]

You're welcome & thanks for the feedback