Unhide next row in multiple column

[rakupareek]

Hi
I have a protected worksheet named "P&L
In which 1-4 rows are headings
And row 5-15 available for data entry
I have made drop-down list in range B5-B15 for expenses and F5-F15 for income
Column C and G for Amount
At the start row 6-15 are hide
And row 5 is first row and being always unhide
My question is....
When I select data from drop-down in range B5-B15 next row automatic unhide.
Same rule will apply on range D5-D15
Please suggest me VBA code for this

 

[kevin9999]

Private Sub Worksheet_Change(ByVal Target As Range)
    If Target.Cells.CountLarge = 1 And Not Intersect(Range("B5:B15,F5:F15"), Target) Is Nothing Then
        On Error GoTo Escape
        Application.EnableEvents = False
        Me.Unprotect Password:="123"
        
        If Cells(Target.Row, 2) & Cells(Target.Row, 6) <> "" Then
            Target.Offset(1).EntireRow.Hidden = False
        ElseIf Cells(Target.Row, 2) & Cells(Target.Row, 6) = "" And Target.Row > 5 Then
            Target.EntireRow.Hidden = True
        End If
        
    End If
Continue:
    Application.EnableEvents = True
    Me.Protect Password:="123"
    Exit Sub
Escape:
    MsgBox "Error " & Err.Number & ": " & Err.Description
    Resume Continue
End Sub

 

[rakupareek]

Code is working perfectly
Thank u very much

 

[kevin9999]

Happy to help, and welcome to the Forum