Use If Statement to Delete Entire Column Based on Specific Text of a Cell

[jewkes6000]

I am trying to cycle through several columns and delete the columns which have the word "HIDE" in a specific cell. I'm able to cycle through the cells; however, whenever a cell contains the word "Hide", it skips it as if the statement is NOT true. The cell does contain a formula which generates the cell value, but I though the code should still recognize the value. Why is the if statement "skipping" to the next column when the cell actually says "Hide"? I've also included a google drive link below to see the actual file.

Any help is much appreciated.

Sub Delete_Columns()

'This will cycle through columns and delete those which are marked as "hide"
    For i = 22 To 237
        Columns(i).Select
        
        If ActiveCell = "Hide" Then
        Columns(i).Delete
        Else
        ActiveCell.Offset(1, 0).Range("A1").Select
        End If

        If ActiveCell = "Hide" Then
        Columns(i).Delete
        Else
        End If
    
    Next i
      
End Sub

Delete Columns Bases on Text (Mr Excel).xlsm

drive.google.com

 

[Joe4]

Perhaps case is the issue.

Try changing these references:

ActiveCell = "Hide"

to this:

UCase(ActiveCell) = "HIDE"

By the way, which row are you checking? We can simplify, improve and speed up your code.
If the words always appear in row 1, then you could re-write your code:

Sub Delete_Columns()

    Dim i As Long
    
    Application.ScreenUpdating = False

    For i = 237 To 22 Step -1
        If UCase(Cells(1, i)) = "HIDE" Then Columns(i).Delete
    Next i
    
    Application.ScreenUpdating = True
      
End Sub

 

[jewkes6000]

Thank you Joe4!! This worked great!

 

[Joe4]

You are welcome.
Glad I was able to help.