Userform checkbox code

[CEG]

I have a userform with checkboxes on it and the following code. I am thinking there has to be an easier way to write this, as I have about 15 of them I have to write. Anyone...?

If chk1 = True Then
        Cells(ActiveCell.Row, "DT").Value = "1"
    Else
        Cells(ActiveCell.Row, "DT").Value = "0"
    End If
    If chk2 = True Then
        Cells(ActiveCell.Row, "DU").Value = "1"
    Else
        Cells(ActiveCell.Row, "DU").Value = "0"
    End If
        If chk3 = True Then
        Cells(ActiveCell.Row, "DV").Value = "1"
    Else
        Cells(ActiveCell.Row, "DV").Value = "0"
    End If
    ect...

Thanks
CEG

 

[AlphaFrog]

    Dim r As Long
    r = ActiveCell.Row
    Cells(r, "DT").Value = Abs(chk1)
    Cells(r, "DU").Value = Abs(chk2)
    Cells(r, "DV").Value = Abs(chk3)
    'ect...

 

[CEG]

Thanks AlphaToad...worked good.

 

[Norie]

If the columns move to the right for each checkbox and the checkboxes are all prefixed with chk you could try this.

Dim I As Long
    For I = 1 To 40
        Range("DT" & ActiveCell.Row).Offset(, I - 1) = Me.Controls("chk" & I).Value * -1
    Next I

 

[CEG]

Ok Norie...

I was just gonna ask another question, which your answer may have taken care of. I need to reverse it for the Private Sub UserForm_Initialize

 

[CEG]

This worked for the UserForm_Initialize...

Dim I As Long
    For I = 1 To 20
    If Cells(r, "DT").Offset(, I - 1) = "1" Then
        Me.Controls("chk" & I) = True
    Else: Me.Controls("chk" & I) = False
    End If
    Next I

 

[AlphaFrog]

Or maybe this...

Dim I As Long
    For I = 1 To 20
        Me.Controls("chk" & I).Value = Cells(r, 123 + I).Value = 1
    Next I