UserForm w/2 modules?

[cstimart]

Is it possible to have macro from separate modules utilize the same UserForm? I've tried to do such, but no luck, as I have had to reference specific to the sub/macro that utilizes it...therefore, I've duplicated the form and with each referencing the specific module/sub.

 

[sykes]

Not completely sure if folks understand what you're trying to achieve.

If it helps, I've started a new project, added 2 modules and a userform, and put a label on the userform.

From the first module I've run this code to show the userrform modelessly (to enable other code to run whilst the userform's visible):

Sub shw()
UserForm1.Show modeless
End Sub

.............Then from the other module, I've run this code, and the label caption changes as expected:

Sub nme_lab()
UserForm1.Label1.Caption = "Hello"
End Sub

Is this what you were asking?

 

[cstimart]

I'll try to explain better. I have Module1 and Module2...both have a public variable 'answer'...which is filled by a Userform.

I've had to utilize/duplicate the userform and reference the variables specifically as "Module1.answer = " ....and "Module2.answer = " ...

Ideally, I'd like to have 1 UserForm that the 'answer' will work in both modules.

 

[sykes]

Declaring two variables with the same name is asking for trouble.

Declare the variable AT THE TOP of just one of the modules, and ensure it's public - so it's available to all procedures in the project:

Public answer As String

I've now put a textbox on the userform, and coded the _change event to apply it's value to the variable:

Private Sub TextBox1_Change()
answer = Me.TextBox1.Value
End Sub

Then in module 1 I've put this:

Sub tst_mod_1()
MsgBox answer
End Sub

...and in module 2 I've put this:

Sub tst_mod_2()
MsgBox answer
End Sub

Use this in either module to start the userform:

Sub shw()
UserForm1.Show modeless
End Sub

..........and that should show you how to declare a global variable, apply a value to it from an open userform, and access the variable from anywhere in your project.

When the userform's active, and you've typed something into the textbox, run the msgbox code in both of the modules to test that they're both accessing your "answer" variable.

Does this help?

 

[mikerickson]

Are module1 and module2 both normal modules?
Is answer declared with Dim or Public?

Alternatly, you could make "what the user entered into the form" a function.

If you have UserForm1 with a textbox and two command buttons, and code like this in the userform's code module

' code in Userform code module

Private Sub butOK_Click()
    Me.Hide
End Sub

Private Sub butCancel_Click()
    Unload Me
End Sub

You could put a function like this in a normal module and call that function from anywhere in the project.

' code in normal module

Function userFormsEntry(Optional defaultValue As String) As String
    With UserForm1
        .Caption = "Enter Data"
        .TextBox1 = defaultValue
        .Show
    End With
    
    userFormsEntry = UserForm1.TextBox1
    
    Unload UserForm1
End Function

Sub demo()
    Dim uiValue As String
    
    uiValue = userFormsEntry("my best guess")
    
    If uiValue = vbNullString Then
        MsgBox "cancel pressed"
    Else
        MsgBox "user entered " & uiValue
    End If
End Sub