UserForm1.ListBox1.Selected

[poiu]

Hello,

Please can you tell me how to find if an item within my For Each loop below is selected? I'm aware of the UserForm1.ListBox1.Selected function but am not sure how to apply it to the responsibility_area variable.

For Each responsibility_area In UserForm1.ListBox1.List
        
    [B]' code to check if list item is selected[/B]
 
Next responsibility_area

Thanks,

Poiu

 

[mikerickson]

To check if a ListBox item is checked, one loops on the index.

Dim i As Long

With ListBox1
    For i = 0 to .ListCount - 1
        If .Selected(i) Then
            MsgBox .List(i) & " is selected."
        End If
    Next i
End With

If the ListBox is not multi-select, the .ListIndex property can be used

With ListBox1
    If .ListIndex = -1 Then
        MsgBox "nothing selected"
    Else
        MsgBox .List(.ListIndex) & " is selected."
    End If
End With

If you have a particular item that you are looking for.

With ListBox1
    For i = 0 to .ListCount - 1
        If .Selected(i) And .List(i) = "What I'm looking for" Then
            MsgBox .List(i) & " is selected."
        End If
    Next i
End With

or, in the non-multi-select situation.

With ListBox1
    If .Value = "What I'm looking for" Then MsgBox "It's selected!"
End With

 

[RoryA]

Dim n as long
with UserForm1.ListBox1
  For n = 1 to .ListCount
    If .Selected(n - 1) then
        ' do something
        msgbox .List(n - 1)
    End If
  Next n
End With

 

[Weaver]

you need to look at it this way

with UserForm1.ListBox1
  for i = 0 to .listcount -1 
    if .selected(i) then
      'code here
    end if
  next i
end with

 

[stubarny]

Thank you, works a treat