using class module to avoid public declaration

[tiredofit]

I read on these threads that it is advisable to pass variables via class modules rather than declare publically.

This is stored in Module1:

Public myarray() As Variant

Sub NoClass()

myarray = Range("A1").CurrentRegion.Value

Dim myarrayrows As Long

myarrayrows = UBound(myarray, 1)

Dim newarray() As Variant

ReDim newarray(1 To myarrayrows, 1 To 1) As Variant

Dim Counter As Long

For Counter= 1 To myarrayrows

    newarray(aCounter1) = myarray(Counter, 1)

Next Counter

Range("E1").Resize(myarrayrows, 1).Value = newarray

End Sub

This is stored in a class module, class1:

Option Explicit

Private temparray As Variant

Property Get myarray() As Variant

myarray = temparray

End Property

Property Let myarray(passedarray As Variant)

temparray = passedarray

End Property

This is in module2:

Sub WithClass()

Dim myclass As Class1

Set myclass = New Class1

myclass.myarray = Range("A1").CurrentRegion.Value

Dim myarrayrows As Long

myarrayrows = UBound(myclass.myarray, 1)

Dim newarray() As Variant

ReDim newarray(1 To myarrayrows, 1 To 1) As Variant

Dim CounterAs Long

For Counter= 1 To myarrayrows

    newarray(Counter, 1) = myclass.myarray(Counter, 1)

Next Counter

Range("E1").Resize(myarrayrows, 1).Value = newarray

Set myclass = Nothing

End Sub

Admittedly these programs do literally nothing other than copy what's in column A and pastes it in column E.

To test, fill column A with around 50,000 entries and run Sub NoClass.

Repeat for Sub WithClass.

Sub NoClass takes less than a second to run.

The version with classes is significantly slower. I think it's because it constantly goes to the get property:

For Counter= 1 To myarrayrows

    newarray(Counter, 1) = myclass.myarray(Counter, 1) ' from here it goes to the class module

Next Counter

Can someone please tell me what have I done wrong?

Surely using classes cannot affect the performance by that much?

So how should I amend it to speed it up?

Thanks

 

[Andy Pope]

The reason for the delay when using a class is that you are passing the whole array back every time and then in the module, not the class, you are selecting the specific element of the array.

Your code in WithClass routine

For Counter = 1 To myarrayrows
    newarray(Counter, 1) = myclass.myarray(Counter, 1)
Next Counter

Is actually doing this

For Counter = 1 To myarrayrows
    newarray(Counter, 1) = myclass.myarray()(Counter, 1)
Next Counter

What you need to do instead is extract the specific item from the array stored in the class.

Sub WithClassItem()

Dim myclass As Class1
    
Set myclass = New Class1

myclass.myarray = Range("A1").CurrentRegion.Value

Dim myarrayrows As Long

myarrayrows = UBound(myclass.myarray, 1)

Dim newarray() As Variant

ReDim newarray(1 To myarrayrows, 1 To 1) As Variant

Dim Counter As Long

For Counter = 1 To myarrayrows

    newarray(Counter, 1) = myclass.myarrayItem(Counter, 1)

Next Counter

Range("E1").Resize(myarrayrows, 1).Value = newarray

Set myclass = Nothing

End Sub

with this new property in the class object

Property Get myarrayItem(RowIndex, ColIndex) As Variant

    myarrayItem = temparray(RowIndex, ColIndex)
    
End Property

Timings (seconds) with A1:A50000 populated with row number
No Class 8.74944582137687E-02
With Class 114.13540019235
With Class Item 9.85504419641074E-02