VBA code add ABC character after Dimensions Length Width Height

[Excelpromax123]

Hello everyone. I need a piece of VBA code to add ABC characters behind the size as shown. Thank you everyone

ABC NEW.xlsb

drive.google.com

 

[Peter_SSs]

Try this as one possible way.
Note that this replaces the original data rather than producing the reults in another column like your sample. I wasn't sure what you were after in that regard.

Sub ABC()
  Dim RX As Object
  Dim a As Variant
  Dim i As Long
 
  Set RX = CreateObject("VBScript.RegExp")
  RX.Pattern = "(\d)( X)"
  a = Range("B3", Range("B" & Rows.Count).End(xlUp)).Value
  For i = 1 To UBound(a)
    If RX.Test(a(i, 1)) Then a(i, 1) = RX.Replace(RX.Replace(a(i, 1), "$1A$2"), "$1B$2") & "C"
  Next i
  Range("B3").Resize(UBound(a)).Value = a
End Sub

 

[gravanoc]

Hello everyone. I need a piece of VBA code to add ABC characters behind the size as shown. Thank you everyone

View attachment 91597

ABC NEW.xlsb

drive.google.com

Option Explicit

Sub ABC()
    Dim rng As Range
    Dim strInput As Variant
    Dim strOutput As Variant
    Dim i As Long, j As Long
   
    Set rng = Range("B3:B6")
   
    For i = 0 To rng.Cells.Count - 1
        strInput = Split(rng.Cells(i + 1, 1).Value, " X ")
       
        For j = 0 To UBound(strInput)
            strInput(j) = strInput(j) & WorksheetFunction.Unichar(65 + j)
           
            If j = 0 Then
                strOutput = strInput(j)
            Else
                strOutput = strOutput & " X " & strInput(j)
            End If
        Next j
       
        rng.Cells(i + 1, 2).Value = strOutput
   
    Next i
   
   
End Sub

 

[Snakehips]

Another possibility.

Sub ABC()
Dim lr As Long

lr = Range("B" & Rows.Count).End(xlUp).Row
Range("C3:C" & lr).Formula = "=IF(B3="""","""",SUBSTITUTE(SUBSTITUTE(B3,"" X"",""A X"",1),"" X"",""B X"",2)&""C"")"
Range("C3:C" & lr).Value = Range("C3:C" & lr).Value

End Sub

 

[Excelpromax123]

Try this as one possible way.
Note that this replaces the original data rather than producing the reults in another column like your sample. I wasn't sure what you were after in that regard.

Sub ABC()
  Dim RX As Object
  Dim a As Variant
  Dim i As Long
 
  Set RX = CreateObject("VBScript.RegExp")
  RX.Pattern = "(\d)( X)"
  a = Range("B3", Range("B" & Rows.Count).End(xlUp)).Value
  For i = 1 To UBound(a)
    If RX.Test(a(i, 1)) Then a(i, 1) = RX.Replace(RX.Replace(a(i, 1), "$1A$2"), "$1B$2") & "C"
  Next i
  Range("B3").Resize(UBound(a)).Value = a
End Sub

Thank You