VBA code to call another VBA code if action not taken by user within certain time.

[Sahak]

Hi All,

I need help with a code which will call another code if action not taken by user within certain time.

The scenario is as follows:
The employee should enter his Employee code in textbox of UserForm. If he pushes button “Clock_In”, VBA code right away executes “Record_Punch” code & clears textbox making ready for next employee, if he starts entering his code & did not push “Clock_In” button (for example changed mind or forgot or…) within certain time (for example 15 seconds), then should be executed another VBA code to clear textbox.

Thank you in advance.

 

[Warship]

Place in UserForm1 Mod:

Option Explicit
Dim RunAt
Const TimerSecs As Integer = 15 'seconds of delay before textbox1 clears

Private Sub Clock_In_Click()
  TimerStop
  Record_Punch
  TextBox1 = ""
End Sub

Private Sub TextBox1_Enter()
  TimerStart
End Sub

Private Sub TextBox1_KeyPress(ByVal KeyAscii As MSForms.ReturnInteger)
  'this proceedure resets timer to TimerSecs from last key press
  'delete this proceedure to only allow a total of TimerSecs for input
  TimerStop
  TimerStart
End Sub

Private Sub UserForm_Terminate()
  TimerStop
End Sub

Private Sub TimerStart()
  RunAt = Now + TimeSerial(0, 0, TimerSecs)
  Application.OnTime _
    EarliestTime:=RunAt, _
    Procedure:="ClearTextBox1"
End Sub

Private Sub TimerStop()
  On Error Resume Next
    Application.OnTime _
      EarliestTime:=RunAt, _
      Procedure:="ClearTextBox1", _
      Schedule:=False
  On Error GoTo 0
End Sub

Place in Standard Module:

Private Sub ClearTextBox1()
  UserForm1.TextBox1 = ""
End Sub

 

[Sahak]

Hi Warship,

Thank you VERY much.