VBA Code to Cut & Paste

[kipper19]

Would anyone know if this is possible, see spreadsheet, I would like to cut the data from a cell that shows the first date, ie B8 and paste into cell C5, similar B13 into C10 etc

 

[Alex Blakenburg]

Your data structure looks pretty consistent, assuming this is reliable on a copy of your workbook give this a try.
Note: It assumes you have no formulas in column C. Let me know if that is not the case.

Sub CopyFirstDate()

    Dim ws As Worksheet
    Dim rng As Range
    Dim arr As Variant
    Dim rowLast As Long, i As Long
   
    Set ws = ActiveSheet        ' Ideally change to = Worksheets("Your_Worksheet_Name")
    With ws
        rowLast = .Range("B" & Rows.Count).End(xlUp).Row
        Set rng = .Range("A4:C" & rowLast)
        arr = rng.Value
    End With

    For i = 1 To UBound(arr)
        If Left(arr(i, 1), 7) = "Starts:" Then
            arr(i - 1, 3) = arr(i + 2, 2)
        End If
    Next i
   
    rng.Columns(3).Value = Application.Index(arr, 0, 3)

End Sub

My Data Set in case anyone else wants to have a go at it is below:

20230107 VBA Copy Field with Offset kipper19.xlsm
	A	B	C	D
1
2
3
4	RACE1	8 STARTERS
5	WATC - Performance for: FLASH INVADER
6	Starts:	0	1st	0
7	Place	Meeting	Dist.	Type
8	8 of 8	BLMT 18/12/2023	1000	TRL
9	6 of 7	BLMT 17/07/2023	400	TRL
10	WATC - Performance for: JUST LEROY
11	Starts:	0	1st	0
12	Place	Meeting	Dist.	Type
13	10 of 10	BLMT 18/12/2023	1000	TRL
14	4 of 8	BLMT 31/07/2023	1000	TRL
15	7 of 8	BLMT 17/07/2023	400	TRL
16	WATC - Performance for: TERRATIF
17	Starts:	0	1st	0
18	Place	Meeting	Dist.	Type
19	2 of 9	LARK 27/11/2023	950	TRL
20	3 of 8	BLMT 29/07/2023	1200	2YO SWP
21	4 of 11	PINJ 20/07/2023	1200	MDN
22	2 of 10	BLMT 05/07/2023	1000	2YO 0MW
23	7 of 11	LARK 26/06/2023	950	TRL
24	4 of 7	LARK 23/01/2023	950	TRL
Data (3)

 

[kipper19]

Apologies for the late reply Alex, thanks and appreciate it, I'll check it out