VBA Fastest Way to Clear Cells

[anthonyexcel]

Good afternoon,

Can someone please show me the fastest wat to clear all cells except for the value EXT. I have been using the code below but it is taking forever!

Sub moveit()
For Each cell In Selection
    If cell.Value <> "EXT" Then cell.Clear
Next
End Sub

 

[RSXchin]

How large are your selections typically?

 

[anthonyexcel]

About 10000 to 15000 rows

 

[shg]

Are the cells literal text or the result of formula?

What about the other cells in the column?

Assuming it's all just text,

Sub moveit()
    Dim av As Variant
    Dim i As Long
    
    With Intersect(Selection, ActiveSheet.UsedRange)
        av = .Value
        For i = 1 To UBound(av)
            If av(i, 1) <> "EXT" Then av(i, 1) = Empty
        Next i
        .Value = av
    End With
End Sub

 

[mirabeau]

Sub keepEXT()
With Selection
    .Value = Evaluate("If(" & .Address & "=""EXT"",""EXT"","""")")
End With
End Sub

 

[anthonyexcel]

shg,

Appreciate it, you are right it is just text! mirabeau that you also for your approach!

 

[shg]

You're welcome, glad it worked for you.