VBA Question

[wkr6469]

I am trying to set up a macro to evaluate a password for a VBA class i'm taking. The password needs to be 8 characters in lenght, starting with an upper case letter, and must consist entirely or upper case letters or numbers besides that. I have set up a do loop that I think will work, but does anyone know how to set up those kinds of specifications for the password? Especially the one specifically for the first character?

 

[cstimart]

Here's for the 1st letter...

If left(password,1) = Ucase(Left(password,1)) then
.
.
.
End If

 

[VoG]

Try like this

If (Asc(Left(pw), 1)) < 65 or Asc(Left(pw, 1)) > 90 Then
'password fails

 

[wkr6469]

Try like this

If (Asc(Left(pw), 1)) < 65 or Asc(Left(pw, 1)) > 90 Then
'password fails

Could you explain what that means exactly?

 

[cstimart]

It's looking at the Leftmost character and making sure it's ascii # is 65 to 90...or a Capital Letter.

http://www.techonthenet.com/ascii/chart.php

 

[gregtx81]

Checking ascii codes might be more straight forward, but this will, perhaps, expand your coding horizons.

Sub testpassword()

    pass = "ABCD1234"
    MsgBox (checkValidPassword(pass))

End Sub



Function checkValidPassword(ByVal pwd As String) As Boolean
    If Len(pwd) <> 8 Then Exit Function
    If Not isUpperCaseLetter(Mid(pwd, 1, 1)) Then Exit Function
    
    checkValidPassword = True
    For i = 2 To Len(pwd)
        If Not myIsNumber(Mid(pwd, i, 1)) And Not isUpperCaseLetter(Mid(pwd, i, 1)) Then checkValidPassword = False
    Next i


End Function

Function isUpperCaseLetter(ByVal c As String) As Boolean
    If Len(c) <> 1 Then Exit Function
    If UCase(c) <> LCase(c) Then                            'verify the character is a letter
        If UCase(c) = c Then isUpperCaseLetter = True       'verify that the letter is uppercase
    End If
End Function

Function myIsNumber(ByVal c As String) As Boolean
    Dim i As Integer
    
    If Len(c) <> 1 Then Exit Function
    
    On Error Resume Next
    i = c * 1                                   'this creates an error if c is not a number
    If Err.Number = 0 Then myIsNumber = True    'if no error then true
End Function