VBA: save as Microsoft 5.0 via MACRO

[BIGTONE559]

I'm lost as to how to save a spreadsheet as the Microsoft 5.0(95 workbook). I normally use the following to save as CSV files:

ActiveWorkbook.SaveAs Filename:= _
"\\Test\C\TestFolder\" & Range("L2").Value & ".csv", FileFormat:=xlCSV _
, CreateBackup:=False

All help is appreciated.

 

[AlphaFrog]

Try something like this...

ActiveWorkbook.SaveAs Filename:= _
"\\Test\C\TestFolder\" & Range("L2").Value & ".xls", FileFormat:=56

 

[BIGTONE559]

Sub Save_Test()
If Not IsNumeric(Right(Cells(2, 12), 4)) Then
MsgBox ("blah blah bad")
Else
ActiveWorkbook.SaveAs Filename:= _
"\\Master01\C\Gallo\" & Right(Cells(2, 12), 4) & ".xls", FileFormat:=56
ThisWorkbook.Saved = True
MsgBox ("Blah blah #" & Right(Cells(2, 12), 4) & " has been saved and is now available")
End If
End Sub

I got it to work and it goes thru and saves the file properly. However, when it prompts that a file already exists and if i want to save over it, once i hit cancel or no it throws up an error 400. . . with no text in the error box.

Any ideas of a solution?

 

[AlphaFrog]

What solution are you looking for?

1. Automatically overwrite without prompting
2. Prompt to overwrite but not error when canceled
3. Test if the file already exists and just message it already exists (no Overwrite\Cancel prompt).

 

[BIGTONE559]

What solution are you looking for?

1. Automatically overwrite without prompting
2. Prompt to overwrite but not error when canceled
3. Test if the file already exists and just message it already exists (no Overwrite\Cancel prompt).

Door #2

prompt to overwrite but no error when canceled or NO is clicked

 

[AlphaFrog]

Sub Save_Test()
    Dim strFullpath As String
    If Not IsNumeric(Right(Cells(2, 12), 4)) Then
        MsgBox ("blah blah bad")
    Else
        strFullpath = "\\Master01\C\Gallo\" & Right(Cells(2, 12), 4) & ".xls"
        If Dir(strFullpath) <> vbNullString Then
            If MsgBox("File already exists." & vbLf & vbLf & "Do you want to overwrite it?", _
                vbYesNo, "File Exists") = vbNo Then Exit Sub
        End If
        Application.DisplayAlerts = False
            ActiveWorkbook.SaveAs Filename:=strFullpath, FileFormat:=56
        Application.DisplayAlerts = True
        MsgBox ("Blah blah #" & Right(Cells(2, 12), 4) & " has been saved and is now available.")
    End If
End Sub

 

[BIGTONE559]

Thanks Alphafrog. . . the only problem i see is that it's not saving the files in file format:=56. i tried to enter it but as usual i didn't have the right syntax.


If you can include saving the file in excel 5.0 (fileformat:=56) i'd appreciate it.

Thanks

 

[AlphaFrog]

ActiveWorkbook.SaveAs Filename:=strFullpath, FileFormat:=xlExcel5


xlFileFormat Enumeration