Verify data in two sheets

[XLant]

Verify data from sheet2 columns L, N, and O, with data on sheet1 columns L, N, and O, and if they are equal then cut the record from sheet 1 and paste it to the last empty row on sheet 2. I am using Excel 2010, and my OS is Vista. I am very new to Excel coding so it would be much appreciated if you could put lots of comments in the code so to help me understand it.

 

[VoG]

I'm not sure if this is what you want. It is looking for an exact match on the same row

Sub cpare()
Dim LR As Long, i As Long, r As Range
With Sheets("Sheet1")
    LR = .Range("L" & Rows.Count).End(xlUp).Row
    For i = 1 To LR
        With .Range("L" & i)
            If .Value = Sheets("Sheet2").Range("L" & i).Value And .Offset(, 2).Value = Sheets("Sheet2").Range("N" & i).Value And .Offset(, 3).Value = Sheets("Sheet2").Range("O" & i).Value Then
                If r Is Nothing Then
                    Set r = .EntireRow
                Else
                    Set r = Union(r, .EntireRow)
                End If
            End If
        End With
    Next i
End With
If Not r Is Nothing Then r.Copy Destination:=Sheets("Sheet2").Range("A" & Rows.Count).End(xlUp).Offset(1)
End Sub