Why Application.FileSearch doesn't work?

[grautu]

The following code fragment

With Application.FileSearch
   .LookIn = sample_folder
   .
   .
   .
End With

may be useful when inspecting the content of sample_folder. I did successfully use that code pattern many times in the past (under Office 2003) but now it fails to work (under Office 2007). Here is the error message which I get:

Run-time error 445
Object doesn't support this action

Indeed, the Application.FileSearch property is not supported, but I can't figure why. Once again, this behaviour appeared after replacing MS Office 2003 with MS Office 2007.
The following items are checked under Tools -> References in my VBA setting:
1. Visual Basic For Application
2. Microsoft Excel 12.0 Object Library
3. OLE Animation
4. Microsoft Office 12.0 Object Library
Can anybody please explain me why Application.FileSearch property fails to work?
Thanks a lot in advance!

 

[Von Pookie]

Filesearch was removed from 2007.

One option would be using Dir instead...

 

[Richard Schollar]

Here's a function I use in 2007 in replacement for Fileserach:

Sub testit() 
    myvar = FileList("C:\Test3") 
    If TypeName(myvar) <> "Boolean" Then 
        For i = LBound(myvar) To UBound(myvar) 
            Debug.Print myvar(i) 
        Next 
    Else 
         MsgBox "No files found" 
    End If 
End Sub 
 
 Function FileList(fldr As String, Optional fltr As String = "*.*") As Variant 
    Dim sTemp As String, sHldr As String 
    If Right$(fldr, 1) <> "\" Then fldr = fldr & "\" 
    sTemp = Dir(fldr & fltr) 
    If sTemp = "" Then 
        FileList = False 
        Exit Function 
    End If 
    Do 
        sHldr = Dir 
        If sHldr = "" Then Exit Do 
        sTemp = sTemp & "|" & sHldr 
     Loop 
    FileList = Split(sTemp, "|") 
End Function

 

[grautu]

Thanks a lot!
Anyway it's hardly understanding why to remove FileSearch; just think about how meandring now is to replace the recursive search in the absence of FileSearch.