Worksheet Name Does Not Contain

[BrittKnee]

Hi All, I have a script that copies each sheet in a workbook into its own workbook. I am trying to exclude sheets that contain "EEs" and can't seem to get it to recognize this. Any thoughts? Below is my current code:

Sub SplitEachWorksheetDepReport()
Application.ScreenUpdating = False
Application.DisplayAlerts = False

For Each ws In ThisWorkbook.Sheets

If ws.Name Like "EEs*" = False And ws.Name <> "Master" And ws.Name <> "Controls" And ws.Name <> "Check Returns" Then
    ws.Copy
    Application.ActiveWorkbook.SaveAs Filename:="C:\User" & "\" & ws.Name & ".xlsx"
    Application.ActiveWorkbook.Close False
End If
Next
Application.DisplayAlerts = True
Application.ScreenUpdating = True
MsgBox "Complete"
End Sub

 

[Fluff]

Do the sheet names contain, or start with EEs?

 

[Siddharth Rout]

Is this what you are trying?

If sheet name starts with EEs then use

For Each ws In ThisWorkbook.Sheets
    If Not ws.Name Like "EEs*" And ws.Name <> "Master" And _
    ws.Name <> "Controls" And ws.Name <> "Check Returns" Then
        '
        '~~> Your code
        '
    End If
Next ws

If sheet name contains that word then use the below.

For Each ws In ThisWorkbook.Sheets
    If InStr(1, ws.Name, "EEs", vbTextCompare) = 0 And ws.Name <> "Master" And _
    ws.Name <> "Controls" And ws.Name <> "Check Returns" Then
        '
        '~~> Your code
        '
    End If
Next ws

 

[BrittKnee]

Awesome, the second suggestion worked (for if the worksheet contains and does not start with). Thanks!

 

[Fluff]

If you are looking for contains you could also use

If ws.Name Like "*EEs*" = False And ws.Name <> "Master" And ws.Name <> "Controls" And ws.Name <> "Check Returns" Then

you just need the extra * at the start of the string.