Need formula that will return a value from a range with blank cells

[chameleon_crp]

Is there a formula that will tell me what was the last text in a range that has blank cells? All the cells have formulas and the blank cells have formulas with the outcome of "".
Example:

Column A
row 1
row 2 X
row 3 X
row 4
row 5
row 6

column b
row 1 A
row 2
row 3
row 4
row 5
row 6 A

The formula i am looking for would look up the range A1:B6 and look up the last text before the A in column B which should be an X from column A.

 

[DonkeyOte]

Not altogether clear to me how complicated this really is? If you're saying you need to find the first non-null string in Col A that occurs between the first and last "A" reference in Col B and where these "A" references can themselves move ... then perhaps:

=LOOKUP(2,1/((A1:A6<>"")*(ROW(A1:A6)>MATCH("A",B1:B6,0))*(ROW(A1:A6)< MATCH(2,INDEX(1/(B1:B6="A"),0)))),A1:A6)

but I suspect this may be a little brute force for your requirements? Can you elaborate further regards requisite flexibility?

 

[Aladin Akyurek]

This gives the last value that is not a blank (i.e., "")...

=LOOKUP(9.99999999999999E+307,
  SEARCH("?",A1:INDEX(A:A,MATCH(REPT("z",255),A:A))),
  A1:INDEX(A:A,MATCH(REPT("z",255),A:A)))

This can be easily adapted to column B...

=LOOKUP(9.99999999999999E+307,
  SEARCH("?",B1:INDEX(B:B,MATCH(REPT("z",255),B:B))),
  B1:INDEX(B:B,MATCH(REPT("z",255),B:B)))

If you want the last non-blank column A-value that occurs before the non-blank column B-value (not sure this is what is wanted)...

F1, control+shift+enter, not just enter:

=MATCH(9.99999999999999E+307,
  SEARCH("?",B1:INDEX(B:B,MATCH(REPT("z",255),B:B))))-1

F2, just enter:

=LOOKUP(9.99999999999999E+307,
  SEARCH("?",A1:INDEX(A:A,F1)),A1:INDEX(A:A,F1))