Copy Values to an Adjacent Column per unique Customer

[Plokimu77]

Good Morning,

Could a VBA Macro possibly copy the total purchases of a customer found in Column C to Column D for each unique Customer.

Below are two tables, the first table with the raw data and the second table with the final result.

Any help is appreciated.

Thank you




Raw Data Table:

Row	Customer	Purchase
1	Bob	Apple
2	Bob	Banana
3	Bob	Apple
4	Total​	3
5	Joey	Orange
6	Joey	Orange
7	Total​	2
8	Mike	Cherry
9	Mike	Strawberry
10	Mike	Lemon
11	Mike	Apple
	Total​	4

Final Result Table:

Row	Customer	Purchase	Total
1	Bob	Apple	3
2	Bob	Banana
3	Bob	Apple
4	Total​	3
5	Joey	Orange	2
6	Joey	Orange
7	Total​	2
8	Mike	Cherry	4
9	Mike	Strawberry
10	Mike	Lemon
11	Mike	Apple
	Total​	4

 

[Joe4]

Try this code:

Sub MyAddTotals()

    Dim c As String
    Dim r As Long
    Dim lr As Long
    Dim tot As Long
    
    Application.ScreenUpdating = False
    
'   Set which column Customer appears in
    c = "B"
    
'   Find last row in Customer column with data
    lr = Cells(Rows.Count, c).End(xlUp).Row
    
'   Loop through all rows from top tp bottom
    For r = lr To 1 Step -1
'       Check to see value in Customer column
        Select Case Cells(r, c)
        
            Case "Total"
'               See if not last row
                If r <> lr Then
'                   Populate row below with previous total
                    Cells(r, c).Offset(1, 2).Value = tot
                End If
'               Grab next total
                tot = Cells(r, c).Offset(0, 1).Value
                
            Case "Customer"
'               Populate row below with previous total
                Cells(r, c).Offset(1, 2).Value = tot
'               Exit loop
                Exit For
    
        End Select
    Next r
    
    Application.ScreenUpdating = True
    
    MsgBox "Macro complete!"
        
End Sub

As long as your structure you posted is accurate, it should work. The only thing you might need to change is this line here:

    c = "B"

If the "Customer" column is anything other than column "B". Just change it to the correct column letter.

 

[Plokimu77]

Perfect.

Thank you

 

[Joe4]

You are welcome.