Creating a word document from within excel

[StephenBart]

I want to launch a word template from within excel. I can create a hyperlink to the .dotx file no problem. But that opens the template. I am trying to achieve the result where a .doc file version based on the word template opens. Any suggestions?

 

[OaklandJim]

I'll try to assist but I need a while.

 

[OaklandJim]

Sorry, wrong thread

 

[OaklandJim]

I believe that the code below does what you need. It opens a copy of the template file based on the template and allows user to edit that new file.

As always for me, other experts write more elegant, faster code. Maybe someone will chime in with a better approach.

Good Luck!

Option Explicit

Sub CreateWordDocFromTemplate()

    Dim sDocName As String

    Dim sTemplateName As String
    
    Dim sDocPath As String
    
    Dim sTemplatePath As String
    
    sDocName = Format(Now, "yyyy-mm-dd hh-mm-ss") & ".docx"

    sTemplateName = "TestTemplate.dotx"
    
    sDocPath = Environ("UserProfile") & "\Desktop\"
    
    sTemplatePath = Environ("UserProfile") & "\Desktop\"

    Call DoCreateWordDoc(sDocName, sTemplateName, sDocPath, sTemplatePath)

End Sub


'Requires a Reference to Microsoft Word 16.0 Word Object Library
'In VBA editor select Tools => References then find the checkbox for
'Microsoft Word 16.0 Word Object Library and check it (on).

Sub DoCreateWordDoc( _
    psDocName As String, _
    psTemplateName As String, _
    psDocPath As String, _
    psTemplatePath)
    
    Dim wdApp As Word.Application
    
    Dim sSaveAsName As String
    
    Set wdApp = New Word.Application

    With wdApp
        
        .Documents.Add psTemplatePath & psTemplateName

        .ActiveDocument.SaveAs2 psDocPath & psDocName
    
        .Visible = True
            
        .Activate
                    
        .Application.WindowState = xlNormal
    
    End With
    
End Sub

 

[OaklandJim]

I did put together a version that does not require any references. For completeness...

Option Explicit

'Does not require setting reference to the Microsoft Word 16.0 Word Object Library.

Sub DocFromTemplate()

    Dim oWordApp As Object
    
    Dim oWordDoc As Object
    
    Dim sTemplateFolder As String
    
    Dim sTemplateFileName As String
    
    Dim sDocumentFolder As String
    
    Dim sDocumentFileName As String
    
    sTemplateFileName = "TestTemplate.dotx"
    
    sTemplateFolder = Environ("UserProfile") & "\Desktop\"
    
    sDocumentFileName = "CopyOfTemplate.docx"
    
    sDocumentFolder = Environ("UserProfile") & "\Desktop\"
    
    Set oWordApp = CreateObject("Word.Application")
    
    On Error Resume Next
    Kill sDocumentFolder & sDocumentFileName
    On Error GoTo 0
    
    If Dir(sTemplateFolder & sTemplateFileName) <> "" Then     'Check if document exists at given location
        Set oWordDoc = oWordApp.Documents.Open(sTemplateFolder & sTemplateFileName, ReadOnly:=True)
    Else
        MsgBox "The Word template file " & sTemplateFileName & " was not found in" _
               & Chr(10) & sTemplateFolder, vbInformation
        Exit Sub
    End If
    
    With oWordDoc
        .SaveAs2 sDocumentFolder & sDocumentFileName
        .Activate
    End With
    
    With oWordApp
        .Visible = True
        .Activate
        .Application.WindowState = xlNormal
    End With
    
End Sub