Deleting Comments and Highlights upon saving a workbook

[NeverALegend]

I have a workbook to which I want to have a beforesave run in which I delete both comments and highlights, I have not been able to achieve it in the last few weeks, I've searched for possible solutions among other co workers, I was suggested the tracking system inside excel but this is a worksheets is based on an excel table. so far I have the following for removing the highlights and it works well, but I would like to include a way to remove the comments as well

Private Sub Workbook_BeforeSave (ByVal SaveAsUi As Boolean, Cancel As Boolean)
Workbooks("Tracking GB Calculator").Activate
Sheets("Tracking List").Select
Range("C3:C2417").Interior.Color = XlNone

End Sub

Any help is greatly appreciated

 

[Domenic]

Try...

Private Sub Workbook_BeforeSave(ByVal SaveAsUi As Boolean, Cancel As Boolean)
    Dim rngComments As Range
    Dim rngCell As Range

    Workbooks("Tracking GB Calculator").Activate
    Sheets("Tracking List").Select
    Range("C3:C2417").Interior.Color = xlNone
    
    On Error Resume Next
    Set rngComments = Range("C3:C2417").SpecialCells(xlCellTypeComments)
    On Error GoTo 0
    
    If Not rngComments Is Nothing Then
        For Each rngCell In rngComments
            rngCell.Comment.Delete
        Next rngCell
    End If
End Sub

However, here's an alternative, which doesn't require to activate or select...

Private Sub Workbook_BeforeSave(ByVal SaveAsUi As Boolean, Cancel As Boolean)
    Dim rngComments As Range
    Dim rngCell As Range

    With Workbooks("Tracking GB Calculator").Sheets("Tracking List")
        .Range("C3:C2417").Interior.Color = xlNone
        On Error Resume Next
        Set rngComments = .Range("C3:C2417").SpecialCells(xlCellTypeComments)
        On Error GoTo 0
        If Not rngComments Is Nothing Then
            For Each rngCell In rngComments
                rngCell.Comment.Delete
            Next rngCell
        End If
    End With
End Sub

Hope this helps!