Deleting Rows faster, if cell contains

[Levi22]

hi guys

I am using the code below to delete rows, the problem is that this is very slow.
Is there a way i can perform this a bit faster?

Thank you

Sub DeleteRows()
    Dim c As Range
    Dim SrchRng
     
    Set SrchRng = ActiveSheet.Range("i10", ActiveSheet.Range("i1654").End(xlUp))
    Do
        Set c = SrchRng.Find("", LookIn:=xlValues)
        If Not c Is Nothing Then c.EntireRow.Delete
    Loop While Not c Is Nothing
End Sub

 

[John Davis]

Maybe:

Sub Levi22()
Application.Calculation = xlCalculationManual
Application.ScreenUpdating = False
Range("I9:I1654").AutoFilter 1, "="
Range("I10:I1654").SpecialCells(xlCellTypeVisible).EntireRow.Delete
ActiveSheet.AutoFilterMode = False
Application.Calculation = xlCalculationAutomatic
Application.ScreenUpdating = True
End Sub

 

[Jonmo1]

You can make just about any code run significantly faster by turning off calculations / screenupdating / events

Dim PrevCalc As Variant
With Application
    .EnableEvents = False
    .ScreenUpdating = False
    PrevCalc = .Calculation
    .Calculation = xlCalculationManual
End with

'the rest of your code here

'now reset back to true

With Application
    .EnableEvents = True
    .ScreenUpdating = True
    .Calculation = PrevCalc
End with

 

[Joe4]

Try this:

Sub DeleteRows()
    Dim SrchRng As Range
     
    Set SrchRng = ActiveSheet.Range("i10", ActiveSheet.Range("i1654").End(xlUp))
    SrchRng.SpecialCells(xlCellTypeBlanks).EntireRow.Delete
End Sub

 

[Levi22]

Thank you very much guys.

Joe: The cells I am referring to have formulas in them so this code doesn't work. Tried your code when the formulas are removed and it works perfectly fine.

JonMo1: I have tried using your solution but nothing happens.

John: Your tweek did the trick. Appcreciated, thank you very much.

 

[Joe4]

The cells I am referring to have formulas in them so this code doesn't work.

Ah, that was an important bit of information that you might have wanted to mention!

 

[John Davis]

You're welcome. Glad to help out.