Display a heatmap matrix showing % matches to other table values

[digitalx2001]

Hi all! First post (but long time lurker!). I've simplified the scenario and sample data I'm trying to solve to the following:

I'm trying to create a heatmap matrix to show percentage of school classes each person was in with every other person. From the raw data (provided below), I want to generate a unique name list, transpose same across the top, do the gradient conditional formatting for high/low values, etc (this isn't the part I need help on).

This issue I'm having is calculating the values. I've somewhat solved this problem but in a very, very ugly and slow way by adding calculated columns to the raw data and then VBA. Code took like 20 minutes to run since there were hundreds of unique names/classes... and this will have to be run often on brand new data sets, so my method is not really sustainable.

As for the solution (required output shown below).... For each cell in the matrix, it should divide the number of classes that RowName <row name="">was in with ColumnName<column name="">, by RowName<row name="">'s total classes.

For example, Bill has 2 classes total (History and Chemistry). Tom was in 1 of those 2 (History). Hence... 1/2 = 50% in cell C2 in the output below. From Tom's perspective, Bill was in all of his classes (1 class, just History). Hence... 1/1 = 100% in cell B3 below.

Really, I think the answer might boil down to just a single formula, but I couldn't find any other similar solutions online to mimic. If VBA would be better suited or required instead of just a repeated formula, that's fine too (and I'll be using VBA to generate the unique list to build the matrix and formatting anyway). Thanks in advance!

EDIT: This would be for Excel 2010+. Might need to run this on different machines, some of which have 2013, so better safe than sorry.

---

RAW DATA:

Name	Class
Bill	History
Tom	History
Joe	Chemistry
Joe	Art
Bill	Chemistry
Sally	Calculus
Joe	Calculus
John	History
John	Art

<tbody>
</tbody>

REQUIRED OUTPUT:

	A	B	C	D	E	F
1		Bill	Tom	Joe	Sally	John
2	Bill		.5	.5	0	.5
3	Tom	1		0	0	1
4	Joe	.333	0		.333	.333
5	Sally	0	0	1		0
6	John	.5	.5	.5	0

<tbody>
</tbody>

</row></column></row>

 

[shg]

One way:

Row\Col	A​	B​	C​	D​	E​	F​	G​
1​	Name​	Class​					​
2​	Bill	History
3​	Tom	History
4​	Joe	Chemistry
5​	Joe	Art
6​	Bill	Chemistry
7​	Sally	Calculus
8​	Joe	Calculus
9​	John	History
10​	John	Art
11​
12​		Art​	Calculus​	Chemistry​	History​
13​	Bill	​	​	x​	x​		B13 and across and down: {=IF(OR(($A$2:$A$10=$A13)*($B$2:$B$10=B$12)), "x", "")}
14​	Joe	x​	x​	x​	​
15​	John	x​	​	​	x​
16​	Sally	​	x​	​	​
17​	Tom	​	​	​	x​
18​
19​	​	Bill	Joe	John	Sally	Tom
20​	Bill	​	1​	1​	0​	1​	B20 and across and down: {=IF($A20=B$19, "", SUMPRODUCT((INDEX($B$13:$E$17, MATCH($A20, $A$13:$A$17), 0)="x") * (INDEX($B$13:$E$17, MATCH(B$19, $A$13:$A$17), 0)="x")))}
21​	Joe	1​	​	1​	1​	0​
22​	John	1​	1​	​	0​	1​
23​	Sally	0​	1​	0​	​	0​
24​	Tom	1​	0​	1​	0​	​
25​

 

[digitalx2001]

Thanks for the reply. So, maybe I'm missing something - where do we get the percentages from? That's actually the key data: how often RowName is in ColumnName's class, divided by RowName's total classes. Which classes they are in together are completely irrelevant.

 

[digitalx2001]

Oh wait, this actually is it! I didn't notice because my test data didn't have any people with more than 1 class together. I thought it was only returning a 1 if they had any classes together, but it was actually a count. Perfect!

I got it to work by just adding the following to your code for B20...

{=IF($A20=B$19, "", SUMPRODUCT((INDEX($B$13:$E$17, MATCH($A20, $A$13:$A$17), 0)="x") * (INDEX($B$13:$E$17, MATCH(B$19, $A$13:$A$17), 0)="x"))/COUNTIF($A$2:$A$10,$A20))}

 

[shg]

You're welcome.