Excel Formula Find Highest Value according to 2 column

[aqeelnokia99]

Dear All i am looking for Excel formula find highest Value with Unique Column only i have post Example Below what result i need

PO	Qty	ZIP		Result I need
a	3	RAF		d
b	2	ERT		a
c	4	KT		b
d	5	KT

i need to find Value according to Unique Largest value in Column Zip and get result value form PO

 

[Peter_SSs]

As I understand what you want, here is one way using helper columns F & G. Those columns could be hidden after the formulas have been entered in them.

23 06 21.xlsm
	A	B	C	D	E	F	G
1	PO	Qty	ZIP		Result I need	Qty	ZIP
2	a	3	RAF		d	5	KT
3	b	2	ERT		a	3	RAF
4	c	4	KT		b	2	ERT
5	d	5	KT
Max

Cell Formulas
Range	Formula
E2:E5	E2	=IF(F2="","",INDEX(A:A,AGGREGATE(15,6,ROW(C$2:C$5)/((B$2:C$5=F2)*(C$2:C$5=G2)),1)))
F2:F5	F2	=IFERROR(AGGREGATE(14,6,B$2:B$5/ISNA(MATCH(C$2:C$5,G$1:G1,0)),1),"")
G2:G5	G2	=IF(F2="","",INDEX(C:C,AGGREGATE(15,6,ROW(C$2:C$5)/(B$2:B$5=F2),COUNTIF(F$2:F2,F2))))

 

[aqeelnokia99]

Thanks you very very much i am sorry for late reply

 

[Peter_SSs]

Thanks you very very much

You are welcome. Glad to help.