Excel formula to look for a value corresponding to the first non-zero value in different row

[wykh]

Jan Feb Mar Apr May Jun Jul Aug Sept Oct Nov Dec
8___8___8__8
________5__5__5
____________________________________2__2


For the above table, I am looking for a formula in Excel that will first look in each row for the first non-zero value, then return the month (in the top row, row 1) that corresponds to this first non-zero value in one of the rows below (row 2, 3, or 4). So for the first row, the formula will return Jan, March for the 2nd row, and Nov for the 3rd row.

 

[T. Valko]

Assuming no negative numbers.

Try this array formula** :

=IF(COUNTIF(A2:L2,">0"),INDEX(A$1:L$1,MATCH(TRUE,A2:L2>0,0)),"")

** array formulas need to be entered using the key combination of CTRL,SHIFT,ENTER (not just ENTER). Hold down both the CTRL key and the SHIFT key then hit ENTER.

Copy down as needed.

 

[sanrv1f]

Hello and welcome to the board,

try this

Excel Workbook
	A	B	C	D	E	F	G	H	I	J	K	L	M
1	Jan	Feb	Mar	Apr	May	Jun	Jul	Aug	Sept	Oct	Nov	Dec
2	8	8	8	8									Jan
3			5	5	5								Mar
4											2	2	Nov
Sheet4

Cell Formulas
Range	Formula
M2	=INDEX($A$1:$L$1,MATCH(TRUE,INDEX($A2:$L2<>0,0),0))
M3	=INDEX($A$1:$L$1,MATCH(TRUE,INDEX($A3:$L3<>0,0),0))
M4	=INDEX($A$1:$L$1,MATCH(TRUE,INDEX($A4:$L4<>0,0),0))