Excel help

[rrajansg]

I downloaded the following information in txt format and converted into excel.

Available
Department A

Salaries 2
Rent 3
Legal 4

Department B

Salaries 34
Rent 25
Legal 38


Need information like this in Excel. Any help in excel formula or macro

Department A Rent 3
Department B Rent 25

 

[hiker95]

rrajansg,

Welcome to the MrExcel forum.


What version of Excel are you using?

You will generally get much more help (and faster) in this forum if you can post your small samples directly in the forum.

Please attach screenshots of your workbook or a sample workbook that accurately portrays your current workbook on one sheet, and what it should look like 'After' on another sheet.

This makes it much easier to see exactly what you want to do, as well as shows us whether there is a consistent number of rows between tables and such.

Here are three possible ways to post small (copyable) screen shots directly in your post:

Please post a screenshot of your sheet(s), what you have and what you expect to achieve, with Excel Jeanie HTML 4 (contains graphic instructions).
http://www.excel-jeanie-html.de/html/hlp_schnell_en.php

or
RichardSchollar’s beta HTML Maker -...his signature block at the bottom of his post

or
Borders-Copy-Paste



If you are not able to give us screenshots:

To get the most precise answer, it is best to upload/attach a sample workbook (sensitive data scrubbed/removed) that contains an example of your raw data on one worksheet, and on another worksheet your desired results.

The structure and data types of the sample workbook must exactly duplicate the real workbook. Include a clear and explicit explanation of your requirements.

You can upload your workbook to www.box.net and provide us with a link to your workbook.

 

[Domenic]

It looks like the data is contained in a single column. If this is case, assuming that Column A contains the data, try the following macro which will list the desired result starting at C2...

[font=Verdana][color=darkblue]Option[/color] [color=darkblue]Explicit[/color]

[color=darkblue]Sub[/color] test()

    [color=darkblue]Dim[/color] MyData() [color=darkblue]As[/color] [color=darkblue]Variant[/color]
    [color=darkblue]Dim[/color] LastRow [color=darkblue]As[/color] [color=darkblue]Long[/color]
    [color=darkblue]Dim[/color] i [color=darkblue]As[/color] [color=darkblue]Long[/color]
    [color=darkblue]Dim[/color] Cnt [color=darkblue]As[/color] [color=darkblue]Long[/color]
    
    LastRow = Cells(Rows.Count, "A").End(xlUp).Row
    
    [color=darkblue]For[/color] i = 2 [color=darkblue]To[/color] LastRow
        [color=darkblue]If[/color] InStr(1, Cells(i, "A").Value, "Department") > 0 [color=darkblue]Then[/color]
            Cnt = Cnt + 1
            [color=darkblue]ReDim[/color] [color=darkblue]Preserve[/color] MyData(1 [color=darkblue]To[/color] 2, 1 To Cnt)
            MyData(1, Cnt) = Cells(i, "A").Value
        [color=darkblue]ElseIf[/color] InStr(1, Cells(i, "A").Value, "Rent") > 0 [color=darkblue]Then[/color]
            MyData(2, Cnt) = Cells(i, "A").Value
        [color=darkblue]End[/color] [color=darkblue]If[/color]
    [color=darkblue]Next[/color] i
    
    Range("C2").Resize(UBound(MyData, 2), UBound(MyData, 1)) = WorksheetFunction.Transpose(MyData)
    
[color=darkblue]End[/color] [color=darkblue]Sub[/color]
[/font]

 

[rrajansg]

Thanks Domenic

Data is in two columns( one column description and another column figures. But header is one column. After few rows another department information starts. Like this I have many department.

I have to summarise expenses for all departments.

I tried to attach my excel, but could not.

Now I have uploaded in the following link

http://www.rajenconsultancy.com/excel/

file name : test_1

Thanks in advance

 

[hiker95]

rrajansg,

Thanks for the workbook.


Sample raw data in column B of worksheet Sheet1:

Excel Workbook
	B	C
1
2
3	Department A
4
5	Salaries	2
6	Rent	3
7	Legal	4
8
9
10	Department B
11
12	Salaries	34
13	Rent	25
14	Legal	38
15
Sheet1

After the macro in a new worksheet Results:

Excel Workbook
	A	B	C
1
2	Department A	Rent	3
3	Department B	Rent	25
4
Results

Please TEST this FIRST in a COPY of your workbook (always make a backup copy before trying new code, you never know what you might lose).


1. Copy the below code, by highlighting the code and pressing the keys CTRL + C
2. Open your workbook
3. Press the keys ALT + F11 to open the Visual Basic Editor
4. Press the keys ALT + I to activate the Insert menu
5. Press M to insert a Standard Module
6. Where the cursor is flashing, paste the code by pressing the keys CTRL + V
7. Press the keys ALT + Q to exit the Editor, and return to Excel
8. To run the macro from Excel, open the workbook, and press ALT + F8 to display the Run Macro Dialog. Double Click the macro's name to Run it.

Option Explicit
Sub ReorgData()
' hiker95, 03/17/2011
' http://www.mrexcel.com/forum/showthread.php?t=536941
Dim w1 As Worksheet, wR As Worksheet
Dim c As Range, NR As Long
Application.ScreenUpdating = False
Set w1 = Worksheets("Sheet1")
If Not Evaluate("ISREF(Results!A1)") Then Worksheets.Add(After:=w1).Name = "Results"
Set wR = Worksheets("Results")
wR.UsedRange.Clear
Set wR = Worksheets("Results")
For Each c In w1.Range("B1", w1.Range("B" & Rows.Count).End(xlUp))
  If InStr(c, "Department") > 0 Then
    NR = wR.Range("A" & Rows.Count).End(xlUp).Offset(1).Row
    wR.Cells(NR, 1) = c.Value
  ElseIf InStr(c, "Rent") > 0 Then
    wR.Cells(NR, 2) = c.Value
    wR.Cells(NR, 3) = c.Offset(, 1).Value
  End If
Next c
wR.UsedRange.Columns.AutoFit
wR.Activate
Application.ScreenUpdating = True
End Sub

Then run the ReorgData macro.

 

[hiker95]

rrajansg,


The same raw data screenshot as my previous reply.


After the updated macro in worksheet Results:

Excel Workbook
	A	B	C	D
1	Department	Salaries	Rent	Legal
2	Department A	2	3	4
3	Department B	34	25	38
4
Results

Please TEST this FIRST in a COPY of your workbook (always make a backup copy before trying new code, you never know what you might lose).

Option Explicit
Sub ReorgDataV2()
' hiker95, 03/17/2011
' http://www.mrexcel.com/forum/showthread.php?t=536941
Dim w1 As Worksheet, wR As Worksheet
Dim c As Range, NR As Long
Application.ScreenUpdating = False
Set w1 = Worksheets("Sheet1")
If Not Evaluate("ISREF(Results!A1)") Then Worksheets.Add(After:=w1).Name = "Results"
Set wR = Worksheets("Results")
wR.UsedRange.Clear
Set wR = Worksheets("Results")
wR.Range("A1:D1") = [{"Department","Salaries","Rent","Legal"}]
For Each c In w1.Range("B1", w1.Range("B" & Rows.Count).End(xlUp))
  If InStr(c, "Department") > 0 Then
    NR = wR.Range("A" & Rows.Count).End(xlUp).Offset(1).Row
    wR.Cells(NR, 1) = c.Value
  ElseIf InStr(c, "Salaries") > 0 Then
    wR.Cells(NR, 2) = c.Offset(, 1).Value
  ElseIf InStr(c, "Rent") > 0 Then
    wR.Cells(NR, 3) = c.Offset(, 1).Value
  ElseIf InStr(c, "Legal") > 0 Then
    wR.Cells(NR, 4) = c.Offset(, 1).Value
  End If
Next c
wR.UsedRange.Columns.AutoFit
wR.Activate
Application.ScreenUpdating = True
End Sub

Then run the ReorgDataV2 macro.

 

[rrajansg]

Thanks hiker95

I choose second option. It works perfect and I get what I want. You saved a day of my life every month.

Have a great day.

Thanks Domenic for your quick help.

 

[hiker95]

rrajansg,

You are very welcome.

Come back anytime.