Extract data based on 2 criteria (using Index & Match)

[emirmansouri]

I would like to extract data that is equal to High in the "Priority" and does not have a value in "Date Closed".
Basically need to list the High priority jobs which have not been closed, so in the Priority column it must be High and in the Date Closed column it must be a blank.
If these conditions are met then extract the data from the Issue (Column C) and list it in Column L. Then find the next high priority item that has no date closed.

So first one that meets these conditions is "Budget has not been initiated yet" in C2.
But as I have built my code I have not found away to extract data using blank cells as a criteria, hence, my last result shows No8, but this is wrong as it has a date because it was closed.

My criteria will not change, its always the same.

1st Criteria = High
2nd Criteria = Blank Cell (as in there is no closed date)

Here is my code so far and the table below

=IF(ISERROR(INDEX($B$2:$G$61,SMALL(IF($D$2:$D$61=$I$2,ROW($D$2:$D$61)),ROW(1:1))-1,2)),"",INDEX($B$2:$G$62,SMALL(IF($D$2:$D$61=$I$2,ROW($D$2:$D$61)),ROW(1:1))-1,2))

# Issue Priority Date Opened Date Closed Comments Open Issue Priorities Top 5 Issues 1 Budget has not been initiated yet. High 6-May-15 To be expedited High 4 2 TAPL still not selected Low 6-May-15 10-May-15 SDM to take action on an urgent basis Medium Issue 3 Strategy Document Delayed Medium 2-Feb-15 10-May-15 Data missing Low Budget has not been initiated yet. 4 No4 High 6-May-15 No4 5 No5 High 6-May-15 10-May-15 No5 6 No6 Medium 6-May-15 10-May-15 No7 7 No7 High 6-May-15 No8 8 No8 High 6-May-15 10-May-15 9 No9 Low 6-May-15 10-May-15 10 No10 High 6-May-15 <tbody> </tbody>

<tbody>
</tbody>

Please help as I have been searching for 2 days and so far I have not seen this done anywhere.

Thanks in advance.

 

[gaz_chops]

Try

=IFERROR(INDEX($B$2:$G$61,SMALL(IF($F$2:$F$62<>"",IF($D$2:$D$61=$I$2,ROW($D$2:$D$61))),ROW(1:1))-1,COLUMN(A2)),"")

 

[jasonb75]

It looks like the first formula goes in L4 in your sheet, based on that, try

=IFERROR(INDEX($C:$C,SMALL(IF($D$2:$D$61=$I$2,IF($F$2:$F$61="",ROW($F$2:$F$61))),ROWS($L$4:$L4))),"")

 

[gaz_chops]

Think it should be <>""

It looks like the first formula goes in L4 in your sheet, based on that, try

=IFERROR(INDEX($C:$C,SMALL(IF($D$2:$D$61=$I$2,IF($F$2:$F$61="",ROW($F$2:$F$61))),ROWS($L$4:$L4))),"")

 

[gaz_chops]

Think it should be <>""

Oops my bad! You're correct should be =""

 

[jasonb75]

Think it should be <>""

I Don't

But as I have built my code I have not found away to extract data using blank cells as a criteria, hence, my last result shows No8, but this is wrong as it has a date because it was closed.

My criteria will not change, its always the same.

1st Criteria = High
2nd Criteria = Blank Cell (as in there is no closed date)

 

[gaz_chops]

That's why I said

Oops my bad! You're correct should be =""

 

[jasonb75]

Oops, overlapping replies again.

 

[emirmansouri]

Thank you so much jasonb75 & gaz_chops. Does exactly what I require.

: )

 

[gaz_chops]

You're welcome, although Jasonb got it right 1st time.