Find content in column and sort in specific order

[Andy15]

Hi Guys

I am looking for some help with finding some content within a column and re-arranging the order of the found rows to a specific order.

To make it a bit clearer please see below

		score1	score2	score3	score4	score5	score6	score7
		text	text	text	text	text	text	text
123	red	number	number	number	number	number	number	number
124	blu	number	number	number	number	number	number	number
125	grn	number	number	number	number	number	number	number
126	ora	number	number	number	number	number	number	number
127	bla	number	number	number	number	number	number	number
	tom	code1	code1	code1	code1	code1	code1	code1
	ann	code2	code2	code2	code2	code2	code2	code2
	alan	code3	code3	code3	code3	code3	code3	code3
	ellie	code4	code4	code4	code4	code4	code4	code4
	mary	code5	code5	code5	code5	code5	code5	code5
	dave	code6	code6	code6	code6	code6	code6	code6
	lee	code7	code7	code7	code7	code7	code7	code7

<tbody>
</tbody>

The cells I need to reorder will always be in column 2 and will always be in the same order starting with "tom" and ending with "lee"

I would like to run a macro to find the relevant rows and all the relevant columns to the right and reorder them in the following order

	ann	code2	code2	code2	code2	code2	code2
	mary	code5	code5	code5	code5	code5	code5
	ellie	code4	code4	code4	code4	code4	code4
	alan	code3	code3	code3	code3	code3	code3
	tom	code1	code1	code1	code1	code1	code1
	lee	code7	code7	code7	code7	code7	code7
	dave	code6	code6	code6	code6	code6	code6

<tbody>
</tbody>

in the above examples the cells with code1, code2 are for example only, in reality they will be various numbers.

Hope this makes sense

Thanks for any help

 

[footoo]

Sub FT()
Dim rng As Range, LstNum%
Set rng = [B:B].Find("tom").Resize(7)
LstNum = Application.CustomListCount + 2
Application.AddCustomList Array("ann", "mary", "ellie", "alan", "tom", "lee", "dave")
rng.EntireRow.Sort key1:=rng(1), order1:=xlAscending, Header:=xlNo, OrderCustom:=LstNum
LstNum = LstNum - 1
Application.DeleteCustomList LstNum
End Sub

 

[Peter_SSs]

If column A is like your sample, that is populated with values above tom and all blanks for the rows you want to sort & below, you could also try this in a copy of your workbook.

Sub ReOrderNameRows()
  With Cells(Rows.Count, 1).End(xlUp).Offset(1).Resize(7).EntireRow
    .Columns(1).FormulaR1C1 = "=MATCH(RC[1],{""ann"",""mary"",""ellie"",""alan"",""tom"",""lee"",""dave""},0)"
    .Sort Key1:=.Columns(1), Order1:=xlAscending, Header:=xlNo
    .Columns(1).ClearContents
  End With
End Sub

 

[Peter_SSs]

If column A is like your sample, that is populated with values above tom and all blanks for the rows you want to sort & below,..

With that same assumption and the added assumption that the extent of the columns is determined by the headings in row 1, here is another one to try.

Sub ReOrderNameRows_v2()
  With Cells(Rows.Count, 1).End(xlUp).Offset(1).Resize(7, Cells(1, Columns.Count).End(xlToLeft).Column)
    .Value = Application.Index(.Value, Application.Transpose(Array(2, 5, 4, 3, 1, 7, 6)), Application.Transpose(Evaluate("row(1:" & .Columns.Count & ")")))
  End With
End Sub

Edit: Should also mention that this method does not preserve any formulas (they would be replaced by their results) & any formatting that is particular to cells in one of the rows will not "follow" the data from that row to its new location. So this suggestion is only about values.

 

[Andy15]

Hi footoo,

The code worked perfectly

Many thanks for your time
Andy

 

[Andy15]

Hi Peter_SSs

The information to reorder is in column B, I have tried changing some of the 1's to 2's but I don't know enough to understand what I am doing.

Thaks
Andy

 

[Andy15]

Hi Peter_SSs

The codes in in column B, sorry if that was not clear. I do not understand enough to modify your code

Thanks
Andy

 

[Peter_SSs]

If you had to modify my codes at all, it probably means that my original assumption from post 3 was incorrect as I had already allowed for the names to be in column B. I had assumed that column A was filled above the "tom" row and empty from the "tom" row down (like your posted sample).

If that is not the case, but the number of columns is set by row 1, you could also try this code, though I understand you already have a good working code from footoo. My 'Edit' notes from post 4 would still apply to this code.

Sub ReOrderNameRows_v3()
  With Columns("B").Find("tom").Offset(, -1).Resize(7, Cells(1, Columns.Count).End(xlToLeft).Column)
    .Value = Application.Index(.Value, Application.Transpose(Array(2, 5, 4, 3, 1, 7, 6)), Application.Transpose(Evaluate("row(1:" & .Columns.Count & ")")))
  End With
End Sub

 

[Andy15]

Hi Footoo,

I am not sure why but on further testing, the code sorts as requested but when I try and save the workbook it gives an error Microsoft excel has stopped working.

I then have the options to check if there is solution or close the programme.

Thought it may help someone else that may try code.

Not sure if there is anything obvious why that would happen

Thanks
Andy

 

[Andy15]

Your assumptions were correct and my worksheet is as per sample, the code just seems to make the sheet flicker but nothing changes. I have tried your latest code and that is working brilliantly. Not sure what difference is but I am happy.

The code from Footoo seems to work until I try and save the workbook then it crashes.

Many thanks for your help