Find word in column, bold row & insert rows below

[Winnietp]

Hi, I’m trying to finish my first macro and I’m down to one last glitch. Please help!

I’m working with Excel 2003 and I need a macro that can find the word “Bottomline” whenever it appears in column A, bold that entire row and then insert two empty rows below it. The word will not always be in the same location.

Here’s an example of what I have…

Program
dlfjaldsjfldjf
dfadf
efadfa
afeaf
BOTTOMLINE
efadfa
fdfasdf
fdfafadsf
BOTTOMLINE
jfladjlfja
eardaf
BOTTOMLINE

...and this is what I want.

Program
dlfjaldsjfldjf
dfadf
efadfa
afeaf
BOTTOMLINE


efadfa
fdfasdf
fdfafadsf
BOTTOMLINE


jfladjlfja
eardaf
BOTTOMLINE

Thanks for your help.

Shari

 

[Tom Urtis]

Sub BoldBottomLine()
Application.ScreenUpdating = False
Dim xRow&
For xRow = Cells(Rows.Count, 1).End(xlUp).Row To 2 Step -1
If Cells(xRow, 1).Value = "BOTTOMLINE" Then
Rows(xRow).Font.Bold = True
Rows(xRow + 1).Resize(2).Rows.Insert
End If
Next xRow
Application.ScreenUpdating = True
End Sub

 

[Rick Rothstein]

Give this macro a try (it should be pretty quick)...

Sub BOTTOMLINE()
  Dim A As Range
  Application.ScreenUpdating = False
  With Columns("A")
    .Replace "BOTTOMLINE", "=BOTTOMLINE", xlWhole
    With .SpecialCells(xlCellTypeFormulas)
      .Value = "BOTTOMLINE"
      .EntireRow.Font.Bold = True
      For Each A In .Areas
        A.Offset(1).Resize(2).EntireRow.Insert
      Next
    End With
  End With
  Application.ScreenUpdating = True
End Sub

 

[Winnietp]

Hi Guys,

I'm happy to say that both codes worked and I can finally finish my first-ever (with lots of help) macro.

Thanks so much.

Shari