Generate pdf Run Time Error 13

[ipbr21054]

Hi,
I am currently using the code below to generate a pdf & works fine.

On my worksheet i have a values in the cells shown & this is how i would like the pdf to be named.
Currently the code specifies ("E5") cell only so the pdf is saved / named as A.pdf

I have changed ("E5") to ("E5;J5") hoping to save / name the file as EFGHIL.pdf but then i see the RTE 13

Example of values in cells
E5 A
F5 B
G5 C
H5 D
I5 E
J5 F

Can you advise what is incorrect Thanks

Private Sub EbayPdf_Click()
  Dim sPath As String, strFileName As String
  
  strFileName = "C:\Users\Ian\Desktop\REMOTES ETC\DISCO II CODE\EBAY PDF\" & Range("E5").Value & ".pdf"
     With ActiveSheet
    If Range("E5") = "" Then
    MsgBox "NO CODE SHOWN TO GENERATE PDF", vbCritical, "NO CODE ON SHEET TO CREATE PDF"
    Exit Sub
    End If
    .ExportAsFixedFormat Type:=xlTypePDF, Filename:=strFileName, Quality:=xlQualityStandard, IncludeDocProperties:=True, IgnorePrintAreas:=False
  MsgBox "PDF HAS NOW BEEN GENERATED", vbInformation + vbOKOnly, "GENERATE PDF FILE MESSAGE"
  
  End With
  
  sPath = "C:\Users\Ian\Desktop\REMOTES ETC\DR\DR SCREEN SHOT PDF\"
  strFileName = sPath & Range("E5").Value & ".pdf"
  If Dir(strFileName) <> vbNullString Then
    ActiveWorkbook.FollowHyperlink strFileName
  End If

End Sub

 

[HaHoBe]

Hi Ian,

maybe

Private Sub EbayPdf_Click()
Dim sPath As String, strFileName As String

Const cstrDISCOII As String = "C:\Users\Ian\Desktop\REMOTES ETC\DISCO II CODE\EBAY PDF\"
Const cstrPATH As String = "C:\Users\Ian\Desktop\REMOTES ETC\DR\DR SCREEN SHOT PDF\"

With ActiveSheet
  If Range("E5") = "" Then
    MsgBox "NO CODE SHOWN TO GENERATE PDF", vbCritical, "NO CODE ON SHEET TO CREATE PDF"
    Exit Sub
  End If
  strFileName = WorksheetFunction.TextJoin("", True, .Range("E5:J5")) & ".pdf"
  .ExportAsFixedFormat Type:=xlTypePDF, _
                        Filename:=cstrDISCOII & strFileName, _
                        Quality:=xlQualityStandard, _
                        IncludeDocProperties:=True, _
                        IgnorePrintAreas:=False, _
                        OpenAfterPublish:=False
  MsgBox "PDF HAS NOW BEEN GENERATED", vbInformation + vbOKOnly, "GENERATE PDF FILE MESSAGE"

End With

'pdf has been created in different folder so I would expect something like
'strFileName = cstrDISCOII & strFileName

strFileName = cstrPATH & strFileName
If Dir(strFileName) <> vbNullString Then
  ActiveWorkbook.FollowHyperlink strFileName
End If

End Sub

I saw that you save the pdf into one folder but the hyperlink leads to a different one. If it*s the same folder for both actions strFileName may be filled with the path as well, be applicated to save and would not have to be filled again to follow the hyperlink.

Holger

 

[ipbr21054]

Thanks very much