get numbers between 2 chars second char not always the same

[pencil pusher]

I am trying to get the numbers in between the "+" from data, except if there is a "(" then I want only the numbers between the "+" and the "("

here is an example of the data

5215983+14(BH)+XZD
5215983+13+DFG
0896458+2(YZ)+XZD
5215983+10+XZD
9874289+14+XZD
5215983+8+XZD
5215983+7(HF)+YZD
31531+33+bbb
3135111355+34(be)+dez



The formula that I am using so far is getting this...
14(BH)
13
2(YZ)
10
14
8
7(HF)
33
34(be)


This is what I want
14
13
2
10
14
8
7
33
34

This is my formula

=MID(K5, FIND("+",K5)+1, FIND("+",K5, FIND("+",K5)+1)-FIND("+",K5)-1)

 

[FlameRetired]

See if this does what you want.

=--TRIM(LEFT(SUBSTITUTE(TRIM(MID(SUBSTITUTE(A1,"+",REPT(" ",256)),256,256)),"(",REPT(" ",256)),256))

 

[FlameRetired]

This is shorter.

=--TRIM(MID(SUBSTITUTE(SUBSTITUTE(A1,"+",REPT(" ",256)),"(",REPT(" ",256)),256,256))

 

[pencil pusher]

This is shorter.

=--TRIM(MID(SUBSTITUTE(SUBSTITUTE(A1,"+",REPT(" ",256)),"(",REPT(" ",256)),256,256))

This works! thank you!

 

[FlameRetired]

You're welcome. Glad it helps and thanks for the feedback.