Great code just needs a small fix

[lakke2120]

I found a code that works great for copying multiple workbooks to a master file but it creates a new file and copies to that file and I would like to see if someone could help me with getting it copy to the same workbook that the code is in. Thank you. Here is the complete code:

Sub CopySameSheetFrmWbs()
Dim wbOpen As Workbook
Dim wbNew As Workbook
'Change Path
Const strPath As String = "C:\Users\lap\Desktop\file2\master1\"
Dim strExtension As String

'Comment out the 3 lines below to debug
Application.ScreenUpdating = False
Application.Calculation = xlCalculationManual
On Error Resume Next

ChDir strPath
'Change extension
strExtension = Dir("*.xls")

Set wbNew = Workbooks.Add
'Change Path, Name and File Format
wbNew.SaveAs Filename:="C:\Users\lap\Desktop\file2\Book1.xlsm", FileFormat:=xlWorkbookNormal

Do While strExtension <> ""
Set wbOpen = Workbooks.Open(strPath & strExtension)

With wbOpen
.Sheets("totals").Copy After:=wbNew.Sheets(wbNew.Sheets.Count)
wbNew.Sheets(wbNew.Sheets.Count).Name = wbNew.Sheets(wbNew.Sheets.Count).Cells(1, 1)
.Close SaveChanges:=False
End With

strExtension = Dir
Loop

Application.ScreenUpdating = True
Application.Calculation = xlCalculationAutomatic
On Error GoTo 0
End Sub

 

[Kaper]

instead of this part:

Set wbNew = Workbooks.Add
     'Change Path, Name and File Format
    wbNew.SaveAs Filename:="C:\Users\lap\Desktop\file2\Book1.xlsm", FileFormat:=xlWorkbookNormal

write:

Set wbNew = ThisWorkbook

PS. Please note that for frequent VBA users readability improves when the code tags (button with # singn) are used - as above.